delphi - Delphi XE8：TEdit TextHint 在接收焦点时消失

Question

基本上，我希望我的 TEdits 的 TextHint 在输入第一个字符时消失，而不是在它们获得焦点时消失，例如此 Microsoft 页面上的编辑：登录您的 Microsoft 帐户。有人可以指导我如何实现这一目标吗？

先感谢您。

Answer 1

内置TEdit行为不允许这样做，但您可以从中派生新控件TEdit并覆盖DoSetTextHint。实现应该类似于内部方法，但提供值 1wParam而不是 0。

这是使用拦截器类的解决方案：

unit EditInterceptor;

uses
  Vcl.StdCtrls, System.SysUtils, Winapi.Messages, Windows;

type
  TEdit = class(Vcl.StdCtrls.TEdit)
  protected
    procedure DoSetTextHint(const Value: string); override;
  end;

implementation

uses
  Vcl.Themes, Winapi.CommCtrl;

procedure TEdit.DoSetTextHint(const Value: string);
begin
  if CheckWin32Version(5, 1) and StyleServices.Enabled and HandleAllocated then
    SendTextMessage(Handle, EM_SETCUEBANNER, WPARAM(1), Value);
end;

end.  

确保将此单元放在Vcl.StdCtrls之后的 interface uses 子句中。

Answer 2

根据 Uwe Raabe 的回答，这是一个程序（对于 Delphi 2007，也应该适用于较新版本的 Delphi）：

type
  TCueBannerHideEnum = (cbhHideOnFocus, cbhHideOnText);

procedure TEdit_SetCueBanner(_ed: TEdit; const _s: WideString; _WhenToHide: TCueBannerHideEnum = cbhHideOnFocus);
const
  EM_SETCUEBANNER = $1501;
var
  wParam: Integer;
begin
  case _WhenToHide of
    cbhHideOnText: wParam := 1;
  else //    cbhHideOnFocus: ;
    wParam := 0;
  end;
  SendMessage(_ed.Handle, EM_SETCUEBANNER, wParam, Integer(PWideChar(_s)));
end;

你这样称呼它：

constructor TForm1.Create(_Owner: TComponent);
begin
  inherited;
  TEdit_SetCueBanner(ed_HideOnFocus, 'hide on focus', cbhHideOnFocus);
  TEdit_SetCueBanner(ed_HideOnText, 'hide on text', cbhHideOnText);
end;

虽然它不检查 Windows 版本，但您可能需要添加 Uwe 提供的 if 语句：

if CheckWin32Version(5, 1) and StyleServices.Enabled and _ed.HandleAllocated then

我刚刚用一个禁用运行时主题的项目对其进行了测试：它不起作用。