2

我正在使用re-framecljs 框架，它reagent用作其视图库。我有一个nvd3图形组件，我想在其订阅更新时对其进行更新。

不幸的是，在最初调用:component-did-mount. :component-will-update在初始渲染后不再调用。

我希望图表能够自我更新，因为订阅会通知它正在收听的数据组件正在更改。

这是图形容器组件：

(defn weight-graph-container
  []
  (let [weight  (subscribe [:weight-change])
        bodyfat (subscribe [:bodyfat-change])
        weight-amount (reaction (get @weight :amount))
        weight-unit   (reaction (get @weight :unit))
        bf-percentage (reaction (get @bodyfat :percentage))
        lbm           (reaction (lib/lbm @weight-amount @bf-percentage))
        fat-mass      (reaction (- @weight-amount @lbm))]
    (reagent/create-class {:reagent-render weight-graph
                           :component-did-mount (draw-weight-graph @lbm @fat-mass "lb")
                           :display-name "weight-graph"
                           :component-did-update (draw-weight-graph @lbm @fat-mass "lb")})))

这是图形组件：

(defn draw-weight-graph [lbm fat-mass unit]
  (.addGraph js/nv (fn []
                     (let [chart (.. js/nv -models pieChart
                                     (x #(.-label %))
                                     (y #(.-value %))
                                     (showLabels true))]
                       (let [weight-data [{:label "LBM" :value lbm} {:label "Fat Mass" :value fat-mass}]]
                         (.. js/d3 (select "#weight-graph svg")
                                   (datum (clj->js weight-data))
                                   (call chart)))))))

最后，这是图形渲染成的组件：

(defn weight-graph []
  [:section#weight-graph
   [:svg]])

我错过了什么？谢谢你的帮助。

4

1 回答 1

3

以下代码解决了您的问题：

(defn draw-weight-graph
  [d]
  (let [[lbm fat-mass unit] (reagent/children d)]
    (.addGraph js/nv (fn []
                       (let [chart (.. js/nv -models pieChart
                                       (x #(.-label %))
                                       (y #(.-value %))
                                       (showLabels true))]
                         (let [weight-data [{:label "LBM" :value lbm} {:label "Fat Mass" :value fat-mass}]]
                           (.. js/d3 (select "#weight-graph svg")
                               (datum (clj->js weight-data))
                               (call chart))))))))

(def graph-component (reagent/create-class {:reagent-render weight-graph
                                            :component-did-mount draw-weight-graph
                                            :display-name "weight-graph"
                                            :component-did-update draw-weight-graph}))

(defn weight-graph-container
  []
  (let [weight  (subscribe [:weight-change])
        bodyfat (subscribe [:bodyfat-change])
        weight-amount (reaction (get @weight :amount))
        weight-unit   (reaction (get @weight :unit))
        bf-percentage (reaction (get @bodyfat :percentage))
        lbm           (reaction (lib/lbm @weight-amount @bf-percentage))
        fat-mass      (reaction (- @weight-amount @lbm))]
  (fn []
     [graph-component @lbm @fat-mass "lb"])))
于 2015-07-20T16:27:25.037 回答