5

先来点背景。我目前正在学习一些关于单子解析器组合器的东西。当我尝试从本文（第 16-17 页）转移“chainl1”函数时，我想出了这个解决方案：

let chainl1 p op = parser {
  let! x = p
  let rec chainl1' (acc : 'a) : Parser<'a> =
      let p' = parser {
          let! f = op
          let! y = p
          return! chainl1' (f acc y)
          }
      p' <|> succeed acc
  return! chainl1' x
}

我用一些大的输入测试了这个函数，得到了一个 StackOverflowException。现在我想知道，是否可以重写一个递归函数，它使用一些计算表达式，以某种方式使用尾递归？

当我扩展计算表达式时，我看不出它通常是如何实现的。

let chainl1 p op =
    let b = parser
    b.Bind(p, (fun x ->
    let rec chainl1' (acc : 'a) : Parser<'a> =
        let p' =
            let b = parser
            b.Bind(op, (fun f ->
            b.Bind(p, (fun y ->
            b.ReturnFrom(chainl1' (f acc y))))))
        p' <|> succeed acc
    b.ReturnFrom(chainl1' x)))
4

2 回答 2

6

在您的代码中，以下函数不是尾递归的，因为 - 在每次迭代中 - 它会在p'或之间进行选择succeed：

// Renamed a few symbols to avoid breaking SO code formatter
let rec chainl1Util (acc : 'a) : Parser<'a> = 
  let pOp = parser { 
    let! f = op 
    let! y = p 
    return! chainl1Util (f acc y) } 
  // This is done 'after' the call using 'return!', which means 
  // that the 'cahinl1Util' function isn't really tail-recursive!
  pOp <|> succeed acc

根据您对解析器组合器的实现，以下重写可能会起作用（我不是这里的专家，但可能值得尝试）：

let rec chainl1Util (acc : 'a) : Parser<'a> = 
  // Succeeds always returning the accumulated value (?)
  let pSuc = parser {
    let! r = succeed acc
    return Choice1Of2(r) }
  // Parses the next operator (if it is available)
  let pOp = parser {
    let! f = op
    return Choice2Of2(f) }

  // The main parsing code is tail-recursive now...
  parser { 
    // We can continue using one of the previous two options
    let! cont = pOp <|> pSuc 
    match cont with
    // In case of 'succeed acc', we call this branch and finish...
    | Choice1Of2(r) -> return r
    // In case of 'op', we need to read the next sub-expression..
    | Choice2Of2(f) ->
        let! y = p 
        // ..and then continue (this is tail-call now, because there are
        // no operations left - e.g. this isn't used as a parameter to <|>)
        return! chainl1Util (f acc y) }

一般来说，在计算表达式中编写尾递归函数的模式是有效的。像这样的东西会起作用（对于以允许尾递归的方式实现的计算表达式）：

let rec foo(arg) = id { 
  // some computation here
  return! foo(expr) }

如您所见，新版本与此模式匹配，但原始版本不匹配。

于 2010-06-29T14:44:12.207 回答
2

一般来说，可以编写尾递归计算表达式（参见1和2let! ），即使由于“延迟”机制而具有多个绑定。

在这种情况下，chainl1我认为最后一个陈述是让你陷入困境的原因。

于 2010-06-29T14:41:58.413 回答