8

我真的在和 Elixir 的主管们苦苦挣扎，想知道如何给他们命名以便我可以使用它们。基本上，我只是想启动一个Task我可以向其发送消息的监督。

所以我有以下内容：

defmodule Run.Command do
  def start_link do
    Task.start_link(fn ->
      receive do
        {:run, cmd} -> System.cmd(cmd, [])
      end
    end)
  end
end

项目入口点为：

defmodule Run do
  use Application

  # See http://elixir-lang.org/docs/stable/elixir/Application.html
  # for more information on OTP Applications
  def start(_type, _args) do
    import Supervisor.Spec, warn: false

    children = [
      # Define workers and child supervisors to be supervised
      worker(Run.Command, [])
    ]

    # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
    # for other strategies and supported options
    opts = [strategy: :one_for_one, name: Run.Command]
    Supervisor.start_link(children, opts)
  end
end

在这一点上，我什至没有信心我正在使用正确的东西（Task特别是）。基本上，我想要的只是在应用程序启动时生成一个进程或任务或 GenServer 或任何正确的东西，我可以向其发送消息，这些消息本质上会执行System.cmd(cmd, opts). 我希望这个任务或过程受到监督。当我向它发送一条{:run, cmd, opts}消息时，例如{:run, "mv", ["/file/to/move", "/move/to/here"]}我希望它生成一个新任务或进程来执行该命令。对于我的使用，我什至不需要从任务中取回响应，我只需要它执行即可。任何关于去哪里的指导都会有所帮助。我已经通读了入门指南，但老实说，它让我更加困惑，因为当我尝试做已经完成的事情时，它永远不会像在应用程序中那样。

谢谢你的耐心。

4

1 回答 1

8

我只会使用 GenServer，设置如下：

defmodule Run do
  use Application

  def start(_, _) do
    import Supervisor.Spec, warn: false

    children = [worker(Run.Command, [])]
    Supervisor.start_link(children, strategy: :one_for_one)
  end
end

defmodule Run.Command do
  use GenServer

  def start_link do
    GenServer.start_link(__MODULE__, [], name: __MODULE__)
  end

  def run(cmd, opts) when is_list(opts), do: GenServer.call(__MODULE__, {:run, cmd, opts})
  def run(cmd, _), do: GenServer.call(__MODULE__, {:run, cmd, []})

  def handle_call({:run, cmd, opts}, _from, state) do
    {:reply, System.cmd(cmd, opts), state}
  end
  def handle_call(request, from, state), do: super(request, from, state)
end

然后，您可以向正在运行的进程发送一个命令来执行，如下所示：

# If you want the result
{contents, _} = Run.Command.run("cat", ["path/to/some/file"])
# If not, just ignore it
Run.Command.run("cp", ["path/to/source", "path/to/destination"])

基本上我们正在创建一个“单例”进程（只能使用给定名称注册一个进程，并且我们正在使用模块名称注册 Run.Command 进程，因此start_link在进程运行时任何连续调用都会失败。但是，这样可以很容易地设置一个 API（run函数），它可以在另一个进程中透明地执行命令，而调用进程不必知道任何关于它的信息。我在这里使用了callvs cast，但如果它是一个微不足道的改变你永远不会关心结果，也不希望调用进程阻塞。

对于长期运行的东西，这是一个更好的模式。对于一次性的事情，Task更简单，更容易使用，但我GenServer个人更喜欢用于这样的全局流程。

于 2015-07-14T04:13:53.403 回答