0

我写了这段代码，repeat 用于重复 char 到 char 数组。有用。

重复字符串 N 次到字符串数组。 但重复字符串到字符串数组核心转储。

A, A, A, 
AB, AB, AB, 
*** Error in `./untitled': free(): invalid pointer: 0x0000000000400f3d ***
....
....
Aborted (core dumped)

为什么？我的代码：

// --cc='gcc'

[indent=4]

init
    var carray = repeatc ('A', 3)
    for i in carray do stdout.printf ("%c, ", i)
    // A, A, A

    stdout.putc ('\n')
    var sarray = repeats ("AB", 3)
    for i in sarray do stdout.printf ("%s, ", i)
    stdout.putc ('\n')



def repeatc (e: char, n: int): array of char
    var a = new array of char[n]
    Memory.copy (a, &e, sizeof (char))
    Memory.copy (&a[1], a, sizeof (char) * (n - 1)) // gcc
    return a

def repeats (e: string, n: int): array of string
    var a = new array of string[n]
    // WORKS: for var i = 0 to (n - 1) do a[i] = e
    // Memory.copy HOW TO?

    // (CORE DUMPED)
    Memory.copy (a, &e, sizeof (uint8*))
    Memory.copy (&a[1], a, sizeof (uint8*) * (n - 1))
    return a

为什么这个代码核心转储了？以及如何解决？

4

1 回答 1

2

这段代码有几个问题。

[indent=4]

init
    var carray = repeatc ('A', 3)
    for i in carray do stdout.printf ("%c, ", i)
    // A, A, A

实际上，它会打印“A, A, A,”（注意尾随的逗号和空格）。有很多方法可以解决这个问题，最简单的就是做类似stdout.puts (string.joinv (", ", sarray)).

def repeatc (e: char, n: int): array of char
    var a = new array of char[n]
    Memory.copy (a, &e, sizeof (char))

使用 Memory.copy（在 C 中又名 memcpy）复制单个字节有点愚蠢。绝对没有理由不在a[0] = e这里做。它更容易并且性能会更好。

    Memory.copy (&a[1], a, sizeof (char) * (n - 1)) // gcc

这是非常错误的。您告诉它将sizeof (char) * (n - 1)字节从该位置复制a到a. 这与您似乎打算的非常不同，即用数组中第一个字节的值填充 a 的其余部分。实际上你不应该使用Memory.copy，你应该使用Memory.set:Memory.set (a, e, n)可以替换这两Memory.copy行。

也就是说，您真正想要的可能是字符串而不是字符数组。如果是这种情况，您可以替换整个函数并调用string.nfill (3, 'A').

def repeats (e: string, n: int): array of string
    var a = new array of string[n]
    // WORKS: for var i = 0 to (n - 1) do a[i] = e
    // Memory.copy HOW TO?

你仍然需要一个循环。一旦你开始尝试使用Memory.*你正在使用指针的函数，那么你需要了解内存是如何布局的。字符串实际上只是字符数组，而数组只是指向数组中第一个元素的指针。当您创建一个字符串数组时，您拥有的是指向指针（在 C 中gchar**）的指针，而不是指向可以开始将字符数据复制到其中的大型连续块的指针。

我猜您正在尝试使用Memory.copy而不是循环和简单的分配来提高性能；这里唯一真正对性能不利的事情是一个简单的分配将调用g_strdup它将调用strlen，因此您最终会扫描输入字符串 N 次来计算长度而不是一次。你会得到的最好的可能是这样的：

var elen = e.length
for var i = 0 to (n - 1)
    a[i] = (string) Memory.dup (e, (uint) elen);

如果您真的关心性能，那么您想要做的是返回一个无主字符串数组，这些字符串都指向内存中的同一位置。或者，如果您真正感兴趣的是连接的字符串而不是数组，只需执行类似的操作

def repeatwithsep (e: string, n: int, separator: string): string
    var elen = e.length;
    var slen = separator.length;
    var a = new StringBuilder.sized ((elen * n) + (slen * (n - 1)) + 1);
    for var i = 0 to (n - 1)
        if i != 0
            a.append_len (separator, slen)
        a.append_len (e, elen)
    return (owned) a.str;
于 2015-07-12T21:43:25.983 回答