7

我想使用命名参数将词法文件句柄传递给子例程，但以下内容无法编译：

#!/usr/bin/perl -w
use strict;

my $log_fh;
my $logname = "my.log";

sub primitive {
   my ($fh, $m) = @_;
   print $fh $m;
}

sub sophisticated {
   my ($args) = @_;
   print $args->{m};
   print $args->{fh} $args->{m} ;
}

open $log_fh, ">", $logname;

print $log_fh "Today I learned ...\n";

primitive($log_fh,"... the old way works ...\n");

sophisticated({
   fh=>$log_fh, 
   m=>"... and the new way requires an intervention by SO.",
   });
close $log_fh;

投诉是：

Scalar found where operator expected at ./lexical.file.handle.pl line 15, near
} $args"
(Missing operator before  $args?)

$ perl --version

This is perl, v5.10.1

当我使用传递参数的原始技术时，它可以正常工作，并且命名参数哈希技术适用于消息部分，但不适用于文件句柄部分。我需要新版本的print吗？

4

2 回答 2

17

当您有一个返回文件句柄的复杂表达式（如$args->{fh}）时，您需要通过添加一些额外的花括号来消除语法歧义：

print { $args->{fh} } $args->{m};

这是由于print操作符的设计方式很奇怪，文件句柄和要打印的内容列表之间没有逗号。

或者，您可以先从参数 hashref 中获取文件句柄，例如

my $fh = $args->{fh};
print $fh $args->{m};
于 2010-06-25T18:32:07.063 回答
4

Friedo 的回答涵盖了您的问题，但我想指出一个风格问题。您无需将所有内容包装在匿名哈希中即可模拟命名参数。哈希初始化器只是一个解释为键/值对的列表。将这样的列表传递给 sub 为调用者提供了更简洁的语法：

sub sophisticated {
   my %arg = @_;
   print $arg{m};
   print {$arg{fh}} $arg{m};
}

sophisticated(fh => $log_fh, m => "Hello, world!\n");
于 2010-06-25T18:49:12.180 回答