5

亲爱的 Fortran 程序员，

有人知道，是否可以在 Fortran 2003 或更高版本中声明一个常量（参数）过程指针数组？

如下所示，我有一个切换器函数，它根据传入的整数参数调用不同的函数。它使用一组过程指针（包装在派生中）类型。该数组必须在运行时init()通过例程进行初始化，然后才能使用。有什么方法可以在编译期间初始化这个数组并避免这种初始化例程的必要性？然后它也可以定义为，因为它的值在运行期间不会改变。parameter

module testmod
  implicit none

  interface
    function funcInterface() result(res)
      integer :: res
    end function funcInterface
  end interface

  type :: ptrWrap
    procedure(funcInterface), nopass, pointer :: ptr
  end type ptrWrap

  type(ptrWrap) :: switcher(2)

contains

  subroutine init()
    switcher(1)%ptr => func1
    switcher(2)%ptr => func2
  end subroutine init

  function callFunc(ii) result(res)
    integer, intent(in) :: ii
    integer :: res
    res = switcher(ii)%ptr()
  end function callFunc

  function func1() result(res)
    integer :: res
    res = 1
  end function func1

  function func2() result(res)
    integer :: res
    res = 2
  end function func2

end module testmod


program test
  use testmod
  implicit none

  call init()  ! I'd like to get rid of this call.
  print *, callFunc(1)
  print *, callFunc(2)

end program test
4

2 回答 2

2

我不认为这是允许的。根据我对 2008 年标准的阅读，parametera 的属性data object和数据对象类不包括过程或过程指针。

当你给它你的代码时，你的编译器告诉你什么？

于 2015-06-18T18:47:46.610 回答
2

Fortran 2008 permits initialization of procedure pointers and procedure pointer components to procedure targets (versus NULL()). The syntax is consistent with other initializers.

! In the scope of the module.
...
type(ptrWrap), parameter :: switcher(2) = [ptrWrap(func1), ptrWrap(func2)]
...
于 2015-06-20T10:23:18.853 回答