2

以下用于比较两个 Real48（6 字节浮点数）的代码编译并运行，但要么生成无意义的结果，要么生成 AV。

program Project44;

{$APPTYPE CONSOLE}
uses
  System.SysUtils,
  System.Generics.Defaults;

begin
  try
    WriteLn(System.Generics.Defaults.TComparer<Real48>.Default.Compare(100.0,100.0));
    WriteLn('all ok, press space');
  except on E:exception do
    WriteLn(e.Message);
  end;
  ReadLn
end.

它应该输出 0，但如果它没有先炸弹，它会输出-92或其他一些不正确的值。

这个错误是否仍然存在于最新的 XE8 中？如果是这样，之前是否有报道过，我在https://quality.embarcadero.com
上找不到任何内容，但如果有较旧的 QC，我想参考一下。

最后....我如何REAL48使用 比较两种类型TComparer<something>？

编辑：
这是我解决的问题：

interface
...snip...
[Test]
procedure TestReal48;
...snip...  
    TTest<T> = record
  private
    class var Def: System.Generics.Defaults.IComparer<T>;
    class var F: FastDefaults.TComparison<T>;
  public
    class function Real48Comparison(const Left, Right: T): Integer; static;

implementation

procedure TestDefault.TestReal48;
var
  OldDef: System.Generics.Defaults.IComparer<Real48>;
begin
  OldDef:= TTest<Real48>.Def;
  TTest<Real48>.Def:= System.Generics.Defaults.TComparer<Real48>.Construct(TTest<Real48>.Real48Comparison);
  TTest<Real48>.Test(100.0,100.0);
  TTest<Real48>.Test(100000.0,-10000.0);
  TTest<Real48>.Test(0.0,-10000.0);
  TTest<Real48>.Test(100000.0,0.0);
  TTest<Real48>.Test(0.0,0.0);
  TTest<Real48>.Def:= OldDef;
end;
4

1 回答 1

6

该缺陷存在于所有版本的编译器中。由于Real48十多年前已弃用，我希望 Embarcadero 不会改变行为，即使您提交了错误报告。当然，您仍然应该提交错误报告，但在等待修复时我不会屏住呼吸！

您必须构建一个比较器，而不是依赖默认值：

var
  Comparer: IComparer<Real48>;

function Real48Comparison(const Left, Right: Real48): Integer;
begin
  if Left < Right then
    Result := -1
  else if Left > Right then
    Result := 1
  else
    Result := 0;
end;

Comparer := System.Generics.Defaults.TComparer<Real48>.Construct(Real48Comparison);

为什么默认Real48比较器如此失败。好吧，从这里开始：

class function TComparer<T>.Default: IComparer<T>;
begin
  Result := IComparer<T>(_LookupVtableInfo(giComparer, TypeInfo(T), SizeOf(T)));
end;

事实证明，TypeInfo(Real48)产量nil。似乎没有可用的类型信息Real48。可能不是一个很大的惊喜。

然后我们到达这里：

function _LookupVtableInfo(intf: TDefaultGenericInterface; info: PTypeInfo; size: Integer): Pointer;
var
  pinfo: PVtableInfo;
begin
  if info <> nil then
  begin
    pinfo := @VtableInfo[intf, info^.Kind];
    Result := pinfo^.Data;
    if ifSelector in pinfo^.Flags then
      Result := TTypeInfoSelector(Result)(info, size);
    if ifVariableSize in pinfo^.Flags then
      Result := MakeInstance(Result, size);
  end
  else
  begin
    case intf of
      giComparer: Result := Comparer_Selector_Binary(info, size);
      giEqualityComparer: Result := EqualityComparer_Selector_Binary(info, size);
    else
      System.Error(reRangeError);
      Result := nil;
    end;
  end;
end;

我们拿起else分支并打电话Comparer_Selector_Binary。所以我们最终执行了二进制比较。比较实际上是由这个函数执行的：

function Compare_Binary(Inst: PSimpleInstance; const Left, Right): Integer;
begin
  Result := BinaryCompare(@Left, @Right, Inst^.Size);
end;

调用：

function BinaryCompare(const Left, Right: Pointer; Size: Integer): Integer;
var
  pl, pr: PByte;
  len: Integer;
begin
  pl := Left;
  pr := Right;
  len := Size;
  while len > 0 do
  begin
    Result := pl^ - pr^;
    if Result <> 0 then
      Exit;
    Dec(len);
    Inc(pl);
    Inc(pr);
  end;
  Result := 0;
end;

对于真正有价值的类型不会有用。

至于与 ABI 相关的运行时错误Real48。似乎Real48参数总是在堆栈上传递。这与在Compare_Binary.

于 2015-06-10T11:12:40.273 回答