0

我正在尝试将我的 Buildkite（ci 构建服务器）项目状态添加到 zsh 提示符！我编写了一个 ruby​​ 脚本，它可以提取状态并将其放入以冒号分隔的文件中，格式如下：

# .buildkite_status
project1: √
project2: x

√ 和 x 是 ansi 颜色编码的。

在我将 $ci_build 变量/函数添加到 RPROMPT 之前，我有一个可以正常工作的提示！

目前我的提示看起来像；

~/.dotfiles »                                         ± master*:3cce1cb

在我想要的改变之后

~/.dotfiles »                                         ± master*:3cce1cb √

我面临的问题是 ci_build 的引入现在包含了我的提示。经过一周的阅读文档和调整后，我没有建议了。我真的很希望它能够正常工作，但更希望它能够正常工作。

这是问题的图片： https ://www.dropbox.com/s/ufj82ipd7bm0o30/Screenshot%202015-06-11%2016.52.11.png?dl=0

zsh.rc

build_status() {
  current_directory=$(basename $PWD)
  var=$(cat ~/.buildkite_status | grep \^$current_directory: | awk -F':' '{print $2}')
  echo -n $var | tr '\n' ' '
}

local git_formats="%{${fg_bold[yellow]}%}± %b%c%u:%.7i%{${reset_color}%}"
zstyle ':vcs_info:git*' enable git
zstyle ':vcs_info:git*' check-for-changes true
zstyle ':vcs_info:git*' get-revision true
zstyle ':vcs_info:git*' stagedstr "+"
zstyle ':vcs_info:git*' unstagedstr "*"
zstyle ':vcs_info:git*' formats "$git_formats"
zstyle ':vcs_info:git*' actionformats "%a $git_formats"

precmd() {
  vcs_info
  build_status
}

zle-keymap-select() { zle reset-prompt; }
zle -N zle-keymap-select

VI_MODE_INDICATOR="%{$fg_bold[red]%}<%{$fg[red]%}<<%{$reset_color%}"
vi_mode_prompt_info() {
  echo "${${KEYMAP/vicmd/$VI_MODE_INDICATOR}/(main|viins)/}"
}

local cwd='%{${fg_bold[green]}%}$(prompt_pwd)%{${reset_color}%}'
local usr='%{${fg[yellow]}%}$(user_hostname)%{${reset_color}%} '
local char='%(?,%F{cyan}»,%F{red}»)%f '
local git='${vcs_info_msg_0_}$(git_stash) '
local git_author='$(git author > /dev/null || echo "$(git author) ")'
local vi_mode='$(which vi_mode_prompt_info &> /dev/null && vi_mode_prompt_info) '
local bg_job='%{${fg_bold[black]}%}$(prompt_bg_job)%{${reset_color}%} '
local ci_build='%{$(build_status)%} '

PROMPT=$cwd$usr$char
RPROMPT=$vi_mode$bg_job$git_author$git$ci_build
4

1 回答 1

2

该问题是由您包含以下输出的方式引起的build_status：

local ci_build='%{$(build_status)%} '

根据zsh手册

%{...%}

包含一个字符串作为文字转义序列。大括号内的字符串不应更改光标位置

zsh假设$ci_build它只包含转义序列并打印出长度为 0 个字符，同时它还包含显示状态的字符和一个空格，因此实际上长了 2 个字符。

由于终端中没有实际的右对齐，zsh根据其感知长度计算右提示的位置。由于它长了 2 个字符，因此计算出正确的提示符会覆盖行尾，将光标放在下一行。

这个问题的快速解决方法是使用%Ginside%{...%}告诉zsh有字符将被输出。%G代表一个字符，对于更多字符，您可以使用适当的数量%G或将匹配的数字放在%and之间G：

local ci_build='%{$(build_status)%2G} '

更干净的解决方法是将 ANSI 代码（可能还有您正在使用的特殊字符）保留在状态文件之外，并为此使用zsh功能。

于 2015-06-19T09:07:20.767 回答