5

我对这个使用 Math.pas 中的 IFThen 函数的 delphi 两个班轮印象深刻。但是，它首先评估 DB.ReturnFieldI，这是不幸的，因为我需要调用 DB.first 来获取第一条记录。

DB.RunQuery('select awesomedata1 from awesometable where awesometableid = "great"');
result := IfThen(DB.First = 0, DB.ReturnFieldI('awesomedata1'));

（作为一个毫无意义的澄清，因为我已经得到了很多好的答案。我忘了提到 0 是 DB.First 如果它有东西返回的代码，否则可能没有意义）

显然这没什么大不了的，因为我可以让它与五个坚固的衬垫一起工作。但我所需要的只是让 Delphi 先评估 DB.first ，然后再评估 DB.ReturnFieldI 。我不想更改 math.pas 并且我认为这不值得我进行重载 ifthen 因为有 16 个 ifthen 函数。

只要让我知道编译器指令是什么，如果有更好的方法来做到这一点，或者如果没有办法做到这一点，任何人的程序是调用 db.first 并盲目检索他发现的第一件事不是一个真正的程序员。

4

4 回答 4

12

表达式的求值顺序通常是未定义的。（C 和 C++ 的方式相同。Java 总是从左到右计算。）编译器无法控制它。如果您需要以特定顺序评估两个表达式，请以不同的方式编写代码。我真的不会担心代码行数。线路很便宜；尽可能多地使用。如果您发现自己经常使用这种模式，请编写一个将其包装起来的函数：

function GetFirstIfAvailable(DB: TDatabaseObject; const FieldName: string): Integer;
begin
  if DB.First = 0 then
    Result := DB.ReturnFieldI(FieldName)
  else
    Result := 0;
end;

即使评估顺序不同，您的原始代码也可能不是您想要的。即使DB.First 不等于零，ReturnFieldI仍然会评估调用。在调用使用它们的函数之前，所有实际参数都经过全面评估。

无论如何，更改 Math.pas 对您没有帮助。它不控制其实际参数的评估顺序。当它看到它们时，它们已经被评估为布尔值和整数；它们不再是可执行的表达式。

调用约定会影响评估顺序，但仍不能保证。参数被压入堆栈的顺序不需要与确定这些值的顺序相匹配。实际上，如果您发现 stdcall 或 cdecl 为您提供了所需的评估顺序（从左到右），那么它们的评估顺序与它们传递的顺序相反。

pascal调用约定在堆栈上从左到右传递参数。这意味着最左边的参数是堆栈底部的参数，而最右边的参数位于顶部，就在返回地址的下方。如果IfThen函数使用该调用约定，编译器可以通过多种方式实现该堆栈布局：

  1. 您期望的方式，即每个参数都被评估并立即推送：

    push (DB.First = 0)
push DB.ReturnFieldI('awesomedata1')
call IfThen

  2. 从右到左评估参数并将结果存储在临时变量中，直到它们被推送：

    tmp1 := DB.ReturnFieldI('awesomedata1')
tmp2 := (DB.First = 0)
push tmp2
push tmp1
call IfThen

  3. 首先分配堆栈空间，并以方便的顺序进行评估：

    sub esp, 8
mov [esp], DB.ReturnFieldI('awesomedata1')
mov [esp + 4], (DB.First = 0)
call IfThen

请注意，在所有三种情况下都以相同的顺序IfThen 接收参数值，但函数不一定按该顺序调用。

默认的寄存器调用约定也从左到右传递参数，但适合的前三个参数在寄存器中传递。然而，用于传递参数的寄存器也是最常用于评估中间表达式的寄存器。的结果DB.First = 0需要在 EAX 寄存器中传递，但编译器还需要该寄存器来调用ReturnFieldI和调用First。首先评估第二个函数可能更方便一些，如下所示：

call DB.ReturnFieldI('awesomedata1')
mov [ebp - 4], eax // store result in temporary
call DB.First
test eax, eax
setz eax
mov edx, [ebp - 4]
call IfThen

需要指出的另一件事是，您的第一个参数是复合表达式。有一个函数调用和一个比较。没有什么可以保证这两个部分是连续执行的。编译器可能首先通过调用Firstand将函数调用排除在外ReturnFieldI，然后将First返回值与零进行比较。

于 2010-06-16T15:47:15.513 回答
3

调用约定会影响它们的评估方式。
没有编译器定义来控制它。

Pascal是您必须使用来获得此行为的调用约定。

尽管我个人永远不会依赖这种行为。

下面的示例程序演示了它是如何工作的。

program Project2;
{$APPTYPE CONSOLE}
uses SysUtils;

function ParamEvalTest(Param : Integer) : Integer;
begin
  writeln('Param' + IntToStr(Param) + ' Evaluated');
  result := Param;
end;

procedure TestStdCall(Param1,Param2 : Integer); stdCall;
begin
  Writeln('StdCall Complete');
end;

procedure TestPascal(Param1,Param2 : Integer); pascal;
begin
  Writeln('Pascal Complete');
end;

procedure TestCDecl(Param1,Param2 : Integer); cdecl;
begin
  Writeln('CDecl Complete');
end;

procedure TestSafecall(Param1,Param2 : Integer); safecall;
begin
  Writeln('SafeCall Complete');
end;

begin
  TestStdCall(ParamEvalTest(1),ParamEvalTest(2));
  TestPascal(ParamEvalTest(1),ParamEvalTest(2));
  TestCDecl(ParamEvalTest(1),ParamEvalTest(2));
  TestSafeCall(ParamEvalTest(1),ParamEvalTest(2));
  ReadLn;
end.

这将需要您编写自己的 IfThen 函数。

如果你真的希望这是一个单行，你真的可以在 Delphi 中做到这一点。我只是觉得它看起来很丑。

If (DB.First = 0) then result :=  DB.ReturnFieldI('awesomedata1') else result := 0;
于 2010-06-16T15:59:57.457 回答
1

您不能将查询更改为只有一个结果，因此避免执行“第一个”命令吗？就像 ：

SELECT TOP 1 awesomedata1 from awesometable

在访问...

于 2010-06-16T15:36:24.510 回答
0

AFAIK 没有编译器指令来控制它。除非您使用 stdcall/cdecl/safecall 约定，否则参数在堆栈上从左到右传递，但由于默认寄存器约定也可以在寄存器中传递参数，因此可能会发生稍后计算参数并将其放入寄存器就在通话之前。并且因为只有寄存器顺序是固定的（EAX、EDX、ECX）才能用于符合条件的参数，所以可以按任何顺序加载寄存器。您可以尝试强制执行“pascal”调用约定（无论如何，您都需要重写该函数）但恕我直言，如果编译器无法明确保证评估顺序，则依赖此类代码总是很危险。施加评估顺序可能会大大减少可用优化的数量。

于 2010-06-16T15:37:29.593 回答