3

我有一个基于 mod_perl2 的 Web 应用程序，需要连接到 mysql 数据库。我已经以驼鹿角色实现了 SQL 连接细节。

简化后，角色如下所示：

package Project::Role::SQLConnection;

use Moose::Role;
use DBIx::Connector;

has 'connection' => (is => 'rw', lazy_build => 1);
has 'dbh' => (is => 'rw', lazy_build => 1);
has 'db'    => ( is => 'rw', default => 'alcatelRSA');
has 'port'  => ( is => 'rw', default => 3306);
has 'host'  => ( is => 'rw', default => '10.125.1.21');
has 'user'  => ( is => 'rw', default => 'tools');
has 'pwd'   => ( is => 'rw', default => 'alcatel');


#make sure connection is still alive...
before dbh => sub {
    my $self = shift;
    $self->connection->run(fixup => sub { $_->do('show tables') });
};

sub _build_dbh {
    my $self = shift;
    return $self->connection->dbh;
}

sub _build_connection {
    my $self = shift;
    my $dsn = 'DBI:mysql:'.$self->db.';host='.$self->host.';port='.$self->port;
    my $conn = DBIx::Connector->new($dsn, $self->user, $self->pwd);
    return $conn;
}

no Moose::Role;
1;

然后我在所有需要连接到数据库的驼鹿类中使用这个角色

 with qw(Project::Role::SQLConnection);

陈述。

虽然这在创建几个对象时效果很好，但当创建多个对象时我很快就会遇到麻烦。例如，在 httpd 日志中，我收到错误消息：

DBI connect('alcatelRSA;host=10.125.1.21;port=3306','tools',...) 失败：C:/Perl/site/lib/DBIx/Connector.pm 第 30 行的连接太多

我考虑过每次都使用 DBIx::Connectors "disconnect" 调用来关闭与数据库的连接，但是根据需要打开/关闭连接对性能的影响似乎很严重。

你对这个问题有什么替代建议吗？

4

1 回答 1

6

您是否正在复制 dbh 并在DBIx::Connector对象超出范围时使用它？该文档明确表示不要这样做。相反，保存 DBIx::Connector 对象本身，并使用属性中的选项将dbh方法调用委托给它。handles

这就是我所做的（实际上我昨天刚刚发布了这段代码以回应另一个问题；有趣的是 DB 问题是如何成堆出现的）：

has dbixc => (
    is => 'ro', isa => 'DBIx::Connector',
    lazy_build => 1,
    # DO NOT save a copy of the dbh. Use this accessor every time, as
    # sometimes it will change unexpectedly!
    handles => [ qw(dbh) ],
);

sub _build_dbixc
{
    my $this = shift;
    DBIx::Connector->new(
        $this->dsn,
        $this->username,
        $this->password,
        $this->connect_options,
    );
}

sub call_dbh
{
    my $this = shift;
    my $method = shift;
    my @args = @_;

    # the normal behaviour -- pings on every dbh access
    #return $this->dbh->$method(@args);

    # the smart behaviour -- presume the DB connection still works
    $this->dbixc->run(fixup => sub { $_->$method(@args) });
}

您可能还想查看您允许多少个 mod_perl 进程。每个单独的进程或线程必须有自己的数据库连接，但可能不止一个——因此您可能还需要确保上面的代码每个进程只运行一次（即构建一个数据库管理对象） ，并且每次构建此类对象的后续尝试都只会返回现有对象的副本。一种简单的方法是使用MooseX::Singleton，但这会引入其他设计问题。

于 2010-06-15T14:57:08.610 回答