1

如何将 obj 列表转换为 int 类型。我正在尝试使用下面的 map 函数添加两个列表，但它不适用于 obj 列表。

let query f= 
 seq{
let cmd = new OleDbCommand( "SELECT *  FROM F" );
let conn = new OleDbConnection( @"Provider=Microsoft.ACE.OLEDB.12.0;
Data Source=D:\Users\df\Documents\Vfolio.accdb;
Persist Security Info=False;" )

conn.Open()
let DAdapt = new OleDbDataAdapter("SELECT * FROM F",conn)
let DTab = new DataSet()
let i= DAdapt.Fill(DTab)
let rowCol = DTab.Tables.[0].Rows
let rowCount = rowCol.Count
 for i in 0 .. (rowCount - 1) do
           yield f (rowCol.[i])
   }
 let u= query(fun row -> row.[0])
 let a= List.ofSeq u
 let v=query(fun row -> row.[1])
 let b= List.ofSeq v
 let c = List.map2 (fun x y-> x + y) a b

错误消息：“obj”类型不支持运算符“+”

4

1 回答 1

5

因为row.[i]返回 type obj， your uand vbecome seq<obj>，因此 your aand bbecome type List<obj>，因此xandy被推断为具有 type obj，当然，你不能添加两个objs，这正是编译器告诉你的。

如果您确定row.[0]并且row.[1]是某种数字，则应应用适当的演员表，例如：

let u= query(fun row -> row.[0] :?> int)
let a= List.ofSeq u
let v=query(fun row -> row.[1] :?> int)
let b= List.ofSeq v
let c = List.map2 (fun x y-> x + y) a b

您也可以在其他地方应用此演员表，具体取决于您的品味和要求，例如：

let c = List.map2 (fun x y-> (x :?> int) + (y :?> int)) a b

或者：

let a= u |> Seq.cast<int> |> List.ofSeq
let b= v |> Seq.cast<int> |> List.ofSeq

但我最喜欢第一个示例，因为它在最早的已知点应用强制转换并产生最少的额外代码。

但请注意：如果在运行时row.[0]结果不是 a int，您将得到一个InvalidCastException.

PS在您的List.map2通话中，您可以(+)直接指定而不是将其包装在额外的 lambda 中：

List.map2 (+) a b

PPS另外，您的电话似乎List.ofSeq很浪费，因为Seq还有map2：

let u = query(fun row -> row.[0] :?> int)
let v = query(fun row -> row.[1] :?> int)
let c = Seq.map2 (+) u v |> List.ofSeq

PPPS另外，您是否注意到这两个调用中的每一个都query生成了自己的数据库连接、命令、适配器和数据集？您是打算这样做还是您的意思是只有一个连接，然后从结果中获取不同的列？如果是这样，您应该只调用query一次：

let c = query( fun row -> (row.[0] :?> int) + (row.[1] :?> int) ) |> List.ofSeq
于 2015-05-20T15:07:34.417 回答