julia - 在 Jupyter 笔记本中运行代码的单行或短脚本？

Question

我喜欢通过在 Jupyter（nee iJulia）笔记本中零碎地运行脚本来开发脚本。但是，有时我需要在远程系统上进行测试，并且需要将代码复制为 .jl 文件。是否有人已经编写了在 .ipynb 笔记本中运行代码的单行脚本或简短脚本？如果没有，我会在某个时候找到它并在此处发布代码。

Answer 1

这是我写的：

using JSON

get_code_cells(j::Dict) = filter(x->x["cell_type"] == "code", j["cells"])

function parse_code_cell(c::Dict)
    buf = IOBuffer()
    write(buf, "begin\n")
    map(x->write(buf, x), c["source"])
    write(buf, "\nend")

    src = bytestring(buf)
    parse(src)
end

extract_code(cells::Vector) = Expr[parse_code_cell(c) for c in cells]
extract_code(j::Dict) = extract_code(get_code_cells(j))
eval_code(j::Dict) = map(eval, extract_code(j))


# get filename, then parse to json, then run all code
const fn = ARGS[1]
eval_code(JSON.parsefile(fn))

它似乎适用于许多笔记本，但并非适用于所有笔记本。具体来说，它无法运行我拥有的笔记本

using PyCall
@pyimport seaborn as sns

当eval遇到那段代码时，它抱怨@pyimport没有被定义（即使它是由 导出的PyCall）。

如果您有兴趣，我们绝对可以清理它，添加更多参数并将其打包到适当的命令行实用程序中。

---

编辑

现在来点完全不同的...

这个版本会输出到ipython nbconvert，将其写入临时文件，调用include该临时文件来运行代码，然后删除临时文件。这应该更健壮（它通过了另一个失败的示例）。关于清洁/包装的相同评论适用。

const fn = abspath(ARGS[1])
dir = dirname(fn)

# shell out to nbconvert to get a string with code
src = readall(`ipython nbconvert --to script --stdout $fn`)

# Generate random filenamein this directory, write code string to it
script_fn = joinpath(dir, string(randstring(30), ".jl"))
open(script_fn, "w") do f
    write(f, src)
end

# now try to run the file we just write. We do this so we can make sure
# to get to the call `rm(script_fn)` below.
try
    include(script_fn)
catch
    warn("Failed executing script from file")
end

# clean up by deleting the temporary file we created
rm(script_fn)

Answer 2

Julia 包NBInclude.jl使这变得简单：

using NBInclude
@nbinclude("myfile.ipynb")

运行整个笔记本并返回最后评估的单元格的值。