4

我试图了解fieldspragma 的行为，我发现它的记录很差，关于以下划线前缀的字段。这是文档必须说的：

以下划线字符开头的字段名称对类是私有的，对子类不可见。继承的字段可以被覆盖，但如果与 -w 开关一起使用会生成警告。

根据我在下面的测试，这与其实际行为不一致。- 前缀字段不仅_在子类中可见，它们在外部类中也可见（除非我不明白“可见”的含义）。此外，直接访问受限哈希也可以正常工作。

除了查看源代码之外，我在哪里可以找到有关fields编译指示行为的更多信息？

{
    package Foo;
    use strict;
    use warnings;
    use fields qw/a _b __c/;

    sub new {
        my ( $class ) = @_;
        my Foo $self = fields::new($class);
        $self->a = 1; $self->b = 2; $self->c = 3;
        return $self;
    }

    sub a : lvalue { shift->{a}   }
    sub b : lvalue { shift->{_b}  }
    sub c : lvalue { shift->{__c} }
}
{
    package Bar;
    use base 'Foo';
    use strict;
    use warnings;
    use Data::Dumper;

    my $o = Bar->new;
    print Dumper $o; ##$VAR1 = bless({'_b' => 2, '__c' => 3, 'a' => 1}, 'Foo');

    $o->a = 4; $o->b = 5; $o->c = 6;
    print Dumper $o; ##$VAR1 = bless({'_b' => 5, '__c' => 6, 'a' => 4}, 'Foo');

    $o->{a} = 7; $o->{_b} = 8; $o->{__c} = 9;
    print Dumper $o; ##$VAR1 = bless({'_b' => 8, '__c' => 9, 'a' => 7}, 'Foo');
}
4

1 回答 1

7

巧合的是，当我尝试回答完全相同的问题时，我恰好有一个~/codescraps/fields/test.pl两年前的测试脚本。:)

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;

{
   package Foo;
   use fields qw(foo bar _Foo_private);
   use private qw(_really_private);
   sub new {
       my Foo $self = shift;
       unless (ref $self) {
           $self = fields::new($self);
           $self->{_Foo_private} = "this is Foo's secret";
       }
       $self->{foo} = 10;
       $self->{bar} = 20;
       return $self;
   }
}

my $foo = Foo->new;
$foo->{foo} = 42;

# this will generate an error: field does not exist
#$foo->{zap} = 42;

print "_Foo_private: " . $foo->{_Foo_private} . "\n";
$foo->{_Foo_private} = 1;
print "_Foo_private: " . $foo->{_Foo_private} . "\n";

print "_really_private: " . $foo->{_really_private} . "\n";
$foo->{_really_private} = 1;
print "_really_private: " . $foo->{_really_private} . "\n";

print Dumper($foo);

# subclassing
{
   package Bar;
   use base 'Foo';
   use fields qw(baz _Bar_private);        # these fields not shared with Foo
   sub new {
       my $class = shift;
       my $self = fields::new($class);
       $self->SUPER::new();                # init base fields
       $self->{baz} = 10;                  # init own fields
       $self->{_Bar_private} = "this is Bar's secret";
       return $self;
   }
}

my $bar = Bar->new;
# these work fine
$bar->{foo} = 1;
$bar->{bar} = 1;
$bar->{_Bar_private} = 1;

# this will not work - underscored fields are not visible to children
$bar->{_Foo_private} = 1;

当我运行你的代码时，我得到了错误：

No such pseudo-hash field "_b" at test2.pl line 16.

（第 16 行是 sub b 的定义。）您在什么架构上运行它？使用字段 pragma 的对象不是简单的祝福 hashrefs —— 它们是祝福 arrayrefs，例如当我修改你的构造函数时：

sub new {
    my ( $class ) = @_;
    my Foo $self = fields::new($class);
    $self->{a} = 1; $self->{_b} = 2; $self->{__c} = 3;
    print "I look like: ", Data::Dumper::Dumper($self);
    return $self;
}

我懂了：

I look like: $VAR1 = bless( [
                 bless( {
                          'a' => 1
                        }, 'pseudohash' ),
                 1,
                 2,
                 3
               ], 'Bar' );

作为附言，我觉得有必要指出，字段pragma 和随之而来的基本pragma 都已被弃用，强烈建议避免使用它们。如今，如果您希望使用访问器构建一个不错的 OO 模块，可以使用Class::Accessor或直接使用Moose。

于 2010-06-08T21:49:34.290 回答