5

我是 Prolog 的新手。我需要编写一个整数加法器，它将 0-9 之间的数字与其他数字 0-9 相加并产生一个解决方案 0-18。这就是我想要做的：

% pseudo code
add(in1, in2, out) :-
    in1 < 10,
    in2 < 10,
    out < 18.

我希望能够这样称呼它：

要检查它是否是有效的添加：

?- add(1,2,3).
true.
?- add(1,2,4).
false.

缺少一个变量：

?- add(X,2,3).
X = 1.
?- add(1,4,X).
X = 5.

有多个缺失变量：

?- add(X,Y,Z).
% Some output that would make sense.  Some examples could be:
X=1, Y=1, Z=2 ;
X=2, Y=1, Z=3 ......

我意识到这可能是一个非常简单的问题，而且可能非常简单。但是，根据我正在使用的Prolog 教程：

“与统一算术比较运算符不同，运算符不能用于为变量赋值。只有在每边的每个术语都已实例化时才能评估。”

4

3 回答 3

6

所有现代 Prolog 系统都提供有限域约束，它们是可以在所有方向上使用的真实关系（与更底层的算术谓词如 is/2 和 >/2 相比）。在 SWI-Prolog 中：

:- use_module(library(clpfd)).

plus(X, Y, Z) :-
        [X,Y] ins 0..9,
        X + Y #= Z.

您的示例的结果：

?- plus(1,2,3).
true.

?- plus(1,2,4).
false.

?- plus(X,2,3).
X = 1.

?- plus(1,4,X).
X = 5.

?- plus(X,Y,Z).
X in 0..9,
X+Y#=Z,
Y in 0..9,
Z in 0..18.

由于谓词可以在所有方向上使用，因此将其称为“add/3”不再有意义，因为这意味着一个方向，但谓词真正描述了关系何时成立，因此更通用。

于 2010-06-06T01:40:52.800 回答
1

那这个呢？：

add(X,Y,Z) :-
        Z is X + Y,
        X < 10,
        Y < 10,
        Z < 19.

问题：这对于表单查询非常有效，add(1,1,X)因为Z' 在<调用之前已实例化，但在您询问时失败add(X,1,2)。您可以使用var/1来区分查询的类型（var/1告诉您变量是否未实例化），但这听起来很痛苦。

于 2010-06-05T20:22:44.657 回答
0

解决方案：

lessThanTen(9).
lessThanTen(8).
lessThanTen(7).
lessThanTen(6).
lessThanTen(5).
lessThanTen(4).
lessThanTen(3).
lessThanTen(2).
lessThanTen(1).
lessThanTen(0).

addSimple(Add1,Add2,Sol) :-
    lessThanTen(Add1),
    lessThanTen(Add2),
    Sol is Add1+Add2.
于 2010-06-05T17:27:57.853 回答