2

可用的后续行动：有更多详细信息的后续行动，请参阅将 MBF 转换为 IEEE。

我有一些仍在使用的遗留数据，读取二进制文件不是问题，数字格式是。所有浮点数都以 MBF 格式（单和双）保存。我在 MSDN 板上找到了一个关于该主题的主题，但该主题仅涉及 Single 值。我也想尽可能远离 API 调用。

有人有双打的解决方案吗？

编辑：以防万一有人需要它，这是Option Strict我最终得到的 VB.NET 代码（它是兼容的）（随意将其转换为 C# 并进行编辑）：

''' <summary>Converts a MBF Single to an IEEE Single</summary>
''' <param name="src">The MBF Single value</param>
''' <returns>The converted IEEE Single value</returns>
''' <remarks>Here can find some further information about this topic: http://en.wikipedia.org/wiki/Microsoft_Binary_Format http://support.microsoft.com/kb/140520</remarks>
Public Shared Function MTIS(ByVal src As Single) As Single
    Return MTIS(BitConverter.GetBytes(src), 0)
End Function

''' <summary>Converts a MBF Single to an IEEE Single</summary>
''' <param name="src">The source array</param>
''' <param name="startIndex">The start index at which the Single starts</param>
''' <returns>The converted IEEE Single value</returns>
''' <remarks>Here can find some further information about this topic: http://en.wikipedia.org/wiki/Microsoft_Binary_Format http://support.microsoft.com/kb/140520</remarks>
Public Shared Function MTIS(ByVal src() As Byte, ByVal startIndex As Integer) As Single
    Dim mbf(3) As Byte
    Dim ieee(3) As Byte

    Array.Copy(src, startIndex, mbf, 0, 4)

    If mbf(3) <> 0 Then
        Dim sign As Byte = mbf(2) And ToByte(&H80)
        Dim exp As Byte = mbf(3) - ToByte(2) ' -1-128-127 '

        ieee(3) = ieee(3) Or sign
        ieee(3) = ieee(3) Or exp >> 1
        ieee(2) = ieee(2) Or exp << 7
        ieee(2) = ieee(2) Or mbf(2) And ToByte(&H7F)
        ieee(1) = mbf(1)
        ieee(0) = mbf(0)
    End If

    Return BitConverter.ToSingle(ieee, 0)
End Function


''' <summary>Converts a MBF Double to a IEEE Double</summary>
''' <param name="src">The MBF Double value</param>
''' <returns>The converted IEEE Double value</returns>
''' <remarks>Here can find some further information about this topic: http://en.wikipedia.org/wiki/Microsoft_Binary_Format http://support.microsoft.com/kb/140520</remarks>
Public Shared Function MTID(ByVal src As Double) As Double
    Return MTID(BitConverter.GetBytes(src), 0)
End Function

''' <summary>Converts a MBF Double to a IEEE Double</summary>
''' <param name="src">The source array</param>
''' <param name="startIndex">The start index at which the Double starts</param>
''' <returns>The converted IEEE Double value</returns>
''' <remarks>Here can find some further information about this topic: http://en.wikipedia.org/wiki/Microsoft_Binary_Format http://support.microsoft.com/kb/140520</remarks>
Public Shared Function MTID(ByVal src() As Byte, ByVal startIndex As Integer) As Double
    Dim mbf(7) As Byte
    Dim ieee(7) As Byte

    Array.Copy(src, startIndex, mbf, 0, 8)

    If mbf(7) <> 0 Then
        Dim sign As Byte = mbf(6) And ToByte(&H80)
        Dim exp As Int16 = mbf(7) - 128S - 1S + 1023S

        ieee(7) = ieee(7) Or sign
        ieee(7) = ieee(7) Or ToByte(exp >> 4 And &HFF)
        ieee(6) = ieee(6) Or ToByte(exp << 4 And &HFF)

        For i As Integer = 6 To 1 Step -1
            mbf(i) <<= 1
            mbf(i) = mbf(i) Or mbf(i - 1) >> 7
        Next
        mbf(0) <<= 1

        For i As Integer = 6 To 1 Step -1
            ieee(i) = ieee(i) Or mbf(i) >> 4
            ieee(i - 1) = ieee(i - 1) Or mbf(i) << 4
        Next
        ieee(0) = ieee(0) Or mbf(0) >> 4
    End If

    Return BitConverter.ToDouble(ieee, 0)
End Function
4

2 回答 2

2

At this Wiki page there's links to a few different code samples for doing this in C, C++ and Python.

One or more of those should hopefully be relatively easy to convert to some language that suits you.

于 2010-06-04T13:10:23.583 回答
1

Microsoft has published a KB article about this, including a P/Invokable DLL which you can use to make the conversion from MBF to IEEE.

An archived copy of it is available here.

于 2010-06-04T14:15:20.243 回答