3

我知道，关于 group-adjacent 功能的问题已经被问过了。但由于某种原因，我无法让它工作。

我在工作中继承了使用 xslt 的项目，而我的老板不明白学习 xslt 的学习曲线有多陡峭，以及它与过程编程有多么不同。

尽管如此，我还是决心尽可能地学习它，但我仍然必须在学习的同时使用它。解决以下问题的任何帮助将不胜感激。

我有一个格式如下的 xml 文档：

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

目前它基本上没有层次结构，并且包含标记以赋予它结构并包含在整个文件中。我正在尝试将所有 TOC 元素分组并将它们嵌套在包含元素中：

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <Wrapper> <!-- create new element to wrap around TOC and TOCAuth -->
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
  </Wrapper>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

事实证明，这比我预期的要困难。我已经尝试了以下代码的许多不同版本，并且我粘贴了似乎最不出错的版本。我意识到它仍然很糟糕：

<xsl:template match="*">
<xsl:for-each-group select="TOCChap | TOCAuth" group-adjacent="self::TOCChap | self::TOCAuth">
  <xsl:choose>
    <xsl:when test="current-grouping-key()">
      <wrapper>
        <xsl:apply-templates select="current-group()"/>

      </wrapper>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="current-group()"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:for-each-group>

先感谢您。

4

3 回答 3

3

您的尝试不起作用的三个原因：

  1. 您选择了错误的节点集；

  2. 您正在使用联合运算符|而不是逻辑运算符or；

  3. TOCAuth您的文档中没有命名元素。

一旦通过将指令更改为解决这三个问题：

<xsl:for-each-group select="*" group-adjacent="self::TOCChap or self::TOCAu">

您将看到您正在寻找的结果 - 请在此处查看完整的演示：http: //xsltransform.net/jyH9rME

-
顺便说一句，您的情况与 XSLT 2.0 规范中给出的使用示例几乎完全相同group-adjacent- 请参见此处的最后一个示例：http: //www.w3.org/TR/xslt20/#grouping-examples

附言

我不禁想知道为什么不利用<Section/>标记将所有组放在包装器中 - 例如，应用：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/document">
    <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:for-each-group select="*" group-starting-with="Section">
            <wrapper>
                <xsl:apply-templates select="current-group()" />
            </wrapper>  
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

<xsl:template match="Section"/>

</xsl:stylesheet>

您的输入将导致：

:<?xml version="1.0" encoding="utf-8"?>
<document xml:lang="EN">
   <wrapper>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
   </wrapper>
   <wrapper>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
   </wrapper>
   <wrapper>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
   </wrapper>
</document>
于 2015-04-19T03:35:19.400 回答
1

您需要一个类似这样的 XSLT（如果没有层次结构）：

<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* , node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:attribute name="xml:lang">EN</xsl:attribute>
            <xsl:for-each-group select="*" group-adjacent="name() = ('TOCChap','TOCAu')">
                <xsl:choose>
                    <xsl:when test="current-grouping-key()">
                        <Wrapper>
                            <xsl:apply-templates select="current-group()"/>
                        </Wrapper>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="current-group()"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>
于 2015-04-19T03:32:16.917 回答
0 

<xsl:template match="document">
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:for-each-group select="*" group-adjacent="boolean(self::TOCChap | self::TOCAu)">
            <xsl:choose>
                <xsl:when test="current-grouping-key()">
                    <wrapper>
                        <xsl:apply-templates select="current-group()"/>
                    </wrapper>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>

</xsl:template>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

于 2018-07-31T08:57:09.217 回答