algorithm - Groovy 中的简单排名算法

Question

我有一个简短的常规算法，用于根据食物的评级为食物分配排名。这可以在 groovy 控制台中运行。代码运行良好，但我想知道是否有更 Groovy 或功能性更强的方式来编写代码。如果可能的话，认为摆脱previousItem和rank局部变量会很好。

def food = [
  [name:'Chocolate Brownie',rating:5.5, rank:null],
  [name:'Fudge', rating:2.1, rank:null],
  [name:'Pizza',rating:3.4, rank:null],
  [name:'Icecream', rating:2.1, rank:null],
  [name:'Cabbage', rating:1.4, rank:null]]

food.sort { -it.rating }

def previousItem = food[0]
def rank = 1
previousItem.rank = rank
food.each { item ->
  if (item.rating == previousItem.rating) {
    item.rank = previousItem.rank
  } else {
    item.rank = rank
  }
  previousItem = item
  rank++
}

assert food[0].rank == 1
assert food[1].rank == 2
assert food[2].rank == 3
assert food[3].rank == 3    // Note same rating = same rank
assert food[4].rank == 5    // Note, 4 skipped as we have two at rank 3

建议？

Answer 1

这是我的解决方案：

def rank = 1
def groupedByRating = food.groupBy { -it.rating }
groupedByRating.sort().each { rating, items ->
  items.each { it.rank = rank }
  rank += items.size()
}

Answer 2

我没有尝试过，但也许这可以工作。

food.eachWithIndex { item, i ->
    if( i>0 && food[i-1].rating == item.rating ) 
        item.rank = food[i-1].rank
    else
        item.rank = i + 1
}

Answer 3

这是另一种不使用常规注入方法的“本地定义”的替代方法：

food.sort { -it.rating }.inject([index: 0]) { map, current ->
    current.rank = (current.rating == map.lastRating ? map.lastRank : map.index + 1)
    [ lastRating: current.rating, lastRank: current.rank, index: map.index + 1 ]
}