3

我的最终目标是将所有相关文件从一个文件夹复制到另一个文件夹。所以例如我们有C:\Users\Tool\Desktop\test\oldStuff。在文件夹oldStuff中，我们有更多文件夹以及一些mp3、mp4和txt文件。

现在我想做的是将所有小于 GB的mp4文件复制到.mp4C:\Users\Tool\Desktop\test\New_Stuff_Less_than_a_Gig文件，将大于 GB的.mp4文件复制到.C:\Users\Tool\Desktop\test\New_STuff_Bigger_than_a_Gig

我虽然这很容易，但我错了。到目前为止有这个，暂时不用担心文件类型所以就做了*.* 

 procedure TForm4.Button1Click(Sender: TObject);
 var
   f: TSearchRec;
   Dir: string;
 begin
    if not SelectDirectory(Dir,widestring(Dir),Dir) then   Exit;
    FileMode:=0;
    if FindFirst(Dir+'\*.*',faAnyFile,f) = 0 then
    repeat
         try
          if (f.Attr and faDirectory ) < $00000008 then
          CopyFile(PChar(Dir+'\'+f.Name),PChar
 ('C:\Users\Tool\Desktop\test\new\'+f.Name),false);
         except
          on e: exception do
            ShowMessage(E.Message);
         end;
    until findNext(f) <> 0
 end;

这将复制所选文件夹中的任何内容，但不会从所选文件夹中的文件夹中复制任何内容。例如，如果我们拥有C:\Users\Tool\Desktop\test\oldStuff\movie.mp4它将复制Movie.mp4文件，但如果我们拥有C:\Users\Tool\Desktop\test\oldStuff\movies\Movie.mp4它将不会复制Movie.mp4文件。我虽然我可以做这样的事情

CopyFile.size < 1000 (PChar('C:\Users\Tool\Desktop\test\oldStuff\*.*'+f.Name),
                   PChar('C:\Users\Tool\Desktop\test\new_Stuff\'+f.Name),false)

甚至只是

CopyFile (PChar('C:\Users\Tool\Desktop\test\old\*.*'+f.Name),
                   PChar('C:\Users\Tool\Desktop\test\new\'+f.Name),false);

但它没有复制任何东西。

4

1 回答 1

6

这是一个示例（在 XE7 中完成），它可以满足您的需求。显然，您需要对其进行修改以满足您的需要；它具有硬编码的路径信息和文件掩码 (*.png)，并使用常量来决定文件是大还是小。

它基于此示例目录树：

D:\TempFiles
  |--\Test
  |-----\A
  |-----\B
  |--------\SubB   
  |-----\NewFiles
  |-------\Large
  L-------\Small

它在D:\TempFiles\Test及其子文件夹中查找所有.png文件，并将等于或大于 10KB 的文件复制到D:\TempFiles\NewFiles\Large，将小于 10KB 的文件复制到D:\TempFiles\新文件\小.

您需要将IOUtilsand添加Types到您的实施uses子句中。

procedure TForm1.Button1Click(Sender: TObject);
var
  aLargeFiles: TStringDynArray;
  aSmallFiles: TStringDynArray;
const
  LargeSize = 10 * 1024;
  SourcePath = 'D:\TempFiles\Test\';
begin
  aLargeFiles := TDirectory.GetFiles(SourcePath, '*.png',
                   TSearchOption.soAllDirectories,
                   function (const Path: string; const SR: TSearchRec): Boolean
                   begin
                     Result := (SR.Size >= LargeSize);
                   end);
  aSmallFiles := TDirectory.GetFiles(SourcePath, '*.png',
                   TSearchOption.soAllDirectories,
                   function(const Path: string; const SR: TSearchRec):Boolean
                   begin
                     Result := (SR.Size < LargeSize);
                   end);
  CopyFilesToPath(aLargeFiles, 'D:\TempFiles\NewFiles\Large\');
  CopyFilesToPath(aSmallFiles, 'D:\TempFiles\NewFiles\Small\');
end;

procedure TForm1.CopyFilesToPath(aFiles: array of string; DestPath: string);
var
  InFile, OutFile: string;
begin
  for InFile in aFiles do
  begin
    OutFile := TPath.Combine( DestPath, TPath.GetFileName( InFile ) );
    TFile.Copy( InFile, OutFile, True);
  end;
end;
于 2015-03-21T17:19:01.637 回答