0

我在 Java 中使用 Jena 和 Pellet 作为推理器。现在我需要查询特定URI的类，但问题是我事先不知道它是什么样的实例，在什么样的类层次结构中，所以我不能使用过滤选项。使用时：

SELECT * WHERE {<" + uri + "> rdf:type ?x}

它返回所有超类。这个特定示例的层次结构如下所示：

-Thing
 -Person
  -Adult
 -Animal
  -Dog

每个类都有多个实例。我不知道我事先要查询什么样的实例。但是，例如，假设我正在查询属于 Dog 类型的实例的 URI。它还将返回 Animal 和 Thing。但我只希望它返回 Dog。那可能吗？使用 LIMIT 1 仅返回直接超类。

4

1 回答 1

2

Jena 有一种简单的方法可以做到这一点，它提供了一个特殊的谓词来查询直接类型，因此在您的代码中，您可以按如下方式生成查询：

  "SELECT * { <" + ind + "> <" + ReasonerVocabulary.directRDFType + "> ?type }"

或者直接在查询中使用此谓词的 URI：

  SELECT * { <ind> <urn:x-hp-direct-predicate:http_//www.w3.org/1999/02/22-rdf-syntax-ns#type> ?type }

也可以编写一个效率相当低但可移植的 SPARQL 查询来查询直接类型：

  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
  PREFIX owl: <http://www.w3.org/2002/07/owl#> 
  SELECT * { 
    <ind> rdf:type ?directType .
    FILTER NOT EXISTS {
      <ind> rdf:type ?type .
      ?type rdfs:subClassOf ?directType .
      FILTER NOT EXISTS {
         ?type owl:equivalentClass ?directType .
      }
    }
  }

如果没有其他类型的个体是该类型的子类，则类是个体的直接类型。但是直接类型可能具有等价的类。为了处理这些情况，我们必须在查询中使用双重否定。此查询效率低下，因为它首先检索个人的所有类型并过滤非直接的类型。但从好的方面来说，您可以将它与 Jena 以外的不提供专用直接类型谓词的系统一起使用。

于 2015-03-20T01:41:49.960 回答