2

我有一个基于 Starman 的服务器 -

#!/usr/bin/perl
use strict;
use warnings;
use Data::Printer;
use Plack::Builder;

my $app = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};

    # Print environment variables
    p($env);

    return [
        200,
        [ 'Content-Type' => 'text/plain' ],
        [ "Hello, you've been here for ", $session->{counter}++, "th   time!" ],
    ];
};

my $default = sub {
    my $env = shift;
    p($env);
    return [
        '200', [ 'Content-Type' => 'text/html' ],
        ["Welcome to default page"],
    ];
};

builder {
    mount "/validate" => builder {
        enable "Middleware::Authentication"
        enable "Session";
        $app;
    };
    mount "/" => builder { $default };
};

我自己的中间件“身份验证”对用户进行身份验证并返回会话信息（到期时间、会话密钥等）用于会话管理，那么我如何在会话中间件中使用这些信息？

4

2 回答 2

2

如果我理解正确，您的问题仅出在中间件的顺序上。启用Session之前的Auth.

检查以下内容，使用文件存储，会话永久存储。试试看，重新启动你Starman的，计数器将被重新加载。（我使用内联中间件代替您的Authentication.）

#!/usr/bin/env perl
use strict;
use warnings;
use Data::Printer;
use Plack::Builder;

my $app = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};
    return [
        200,
        [ 'Content-Type' => 'text/html' ],
        [
            "My app page is visited ",
            $session->{counter}++,
            "th times! Validation is done at:",
            $session->{mwaretime},
            q{<br><a href="/validate">go validate again</a> --- <a href="/">reload this page</a>}
        ],
    ];
};

my $validate = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};
    $session->{counter} = 0;
    return [
        '200', [ 'Content-Type' => 'text/html' ],
        [
            "Resetting the counter:",
            $session->{counter},
             ". Time from middleware: ",
            $session->{mwaretime},
            q{<br> <a href="/validate">reload this page</a> --- <a href="/">go to index</a> }
        ],
    ];
};

builder {
    #the session will be stored persistently
    #enable the Session BEFORE your middleware
    enable 'Session', store => 'File';

    mount "/validate" => builder {
        #enable "Authentication";
        #following is same as an middleware
        enable sub {
            my $app = shift;
            return sub {
                my $env = shift;
                my $session = $env->{'psgix.session'};
                $session->{mwaretime} = time();
                $app->($env);
            };
        };
        #end of the middleware
        $validate;
    };
    mount "/" => $app 
};
于 2015-03-19T20:33:07.900 回答
1

从您的问题中，很难说出您的要求到底是什么样的。但是，如果您想对会话管理进行如此多的控制，最好编写自己的中间件。也就是说，有一些方法可以适应Plack::Middleware::Session某些场景。但他们中的大多数都或多或少地使用了未记录的功能。这意味着您必须熟悉源代码，并且这些功能可能会在以后的版本中更改或消失。

如果您想提供自己的会话密钥，可以将自定义 SID 生成器和验证器传递给Plack::Session::State：

enable 'Session',
    state => Plack::Session::State->new(
        sid_generator => $my_generator,
        sid_validator => $my_validator,
    );

的文档基本上sid_generator说“只需阅读源代码”。

您还可以实现自己的Plack::Session::Store后端。但在这种情况下，切换到自定义解决方案可能更有意义。

关于 cookie 过期时间，您可以在创建新 cookie之前expires设置选项：$env->{'psgix.session.options'} 

$env->{'psgix.session.options'}{expires} = $my_expires;

这不是超时，而是自 UNIX 纪元以来以秒为单位的时间，或Cookie::Baker.

也许您应该重新考虑您的身份验证中间件是否真的必须生成会话密钥。就像@jm666 所说，您通常在身份验证之前运行会话中间件。然后您的身份验证代码可以访问所有会话信息。会话 ID 通常是会话管理的实现细节，不必涉及代码的其他部分。要更改过期时间，请参阅我对此问题的回答。

于 2015-03-24T11:23:16.437 回答