3

我试图在 Coq的“Practical Coinduction”中证明第一个例子。第一个例子是证明无限整数流上的字典顺序是可传递的。

我无法制定证明来绕过Guardedness 条件

这是我到目前为止的发展。首先是无限流的通常定义。然后定义字典顺序称为lex。最后是传递性定理的失败证明。

Require Import Omega.

Section stream.
  Variable A:Set.

  CoInductive Stream : Set :=
  | Cons : A -> Stream -> Stream.

  Definition head (s : Stream) :=
    match s with Cons a s' => a end.

  Definition tail (s : Stream) :=
    match s with Cons a s' => s' end.

  Lemma cons_ht: forall s, Cons (head s) (tail s) = s.
    intros. destruct s. reflexivity. Qed.

End stream.

Implicit Arguments Cons [A].
Implicit Arguments head [A].
Implicit Arguments tail [A].
Implicit Arguments cons_ht [A].

CoInductive lex s1 s2 : Prop :=
  is_le :   head s1 <= head s2 ->
            (head s1 = head s2 -> lex (tail s1) (tail s2)) ->
            lex s1 s2.


Lemma lex_helper: forall s1 s2,  
        head s1 = head s2 -> 
        lex (Cons (head s1) (tail s1)) (Cons (head s2) (tail s2)) -> 
        lex (tail s1) (tail s2).
Proof. intros; inversion H0; auto. Qed.

这是我要证明的引理。我从准备目标开始，这样我就可以应用构造函数，希望最终能够使用cofix.

Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
  intros s1 s2 s3 lex12 lex23.
  cofix.
  rewrite  <- (cons_ht s1).
  rewrite  <- (cons_ht s3).
  assert (head s1 <= head s3) by (inversion lex12; inversion lex23; omega).
  apply is_le; auto.

  simpl; intros. inversion lex12; inversion lex23.
  assert (head s2 = head s1) by omega.

  rewrite <- H0, H5 in *.
  assert (lex (tail s1) (tail s2)) by (auto).
  assert (lex (tail s2) (tail s3)) by (auto).

  apply lex_helper.
  auto.
  repeat rewrite cons_ht.
  Guarded.

我该如何从这里开始？感谢您的任何提示！

  • 编辑

感谢亚瑟（一如既往！）有帮助和启发性的回答，我也可以完成证明。我在下面给出我的版本以供参考。 

Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
  cofix.
  intros s1 s2 s3 lex12 lex23.
  inversion lex12; inversion lex23.
  rewrite  <- (cons_ht s1).
  rewrite  <- (cons_ht s3).
  constructor; simpl.
  inversion lex12; inversion lex23; omega.
  intros; eapply lex_lemma; [apply H0 | apply H2]; omega.
Qed.

我使用cons_ht引理来“扩展” s1and的值s3。lex这里 (with headand )的定义tail更接近于Practical Coinduction中的逐字表述。Arthur 使用了一种更优雅的技术，它使 Coq 自动扩展值 - 更好！

4

1 回答 1

5

你的证明的一个问题是你在被介绍cofix之后打电话太晚了。s1 s2 s3因此，你得到的协推假设 ,lex s1 s2不是很有用：为了在保持警惕的同时应用它，正如你提到的，我们需要在应用 的构造函数之后lex再做。但是，在这样做之后，我们需要在某个时候证明这一点是lex (tail s1) (tail s3)成立的，其中引入的假设cofix没有任何好处。

为了解决这个问题，我们需要在引入变量cofix 之前执行调用，以便它产生的假设足够普遍。我冒昧地重新定义了 的定义lex，以便在这样的证明中更容易操作：

CoInductive lex : Stream nat -> Stream nat -> Prop :=
| le_head n1 n2 s1 s2 : n1 < n2 -> lex (Cons n1 s1) (Cons n2 s2)
| le_tail n s1 s2 : lex s1 s2 -> lex (Cons n s1) (Cons n s2).

Lemma lex_trans : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
Proof.
  cofix.
  intros s1 s2 s3 lex12 lex23.
  inversion lex12; subst; clear lex12;
  inversion lex23; subst; clear lex23;
  try (apply le_head; omega).
  apply le_tail; eauto.
Qed.

现在，假设具有形式

forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3

只要生成的应用程序受到保护，它就可以很容易地应用于我们流的尾部。

于 2015-03-19T02:33:58.923 回答