25

如何使用新的 haskell-ng 基础架构在 NixOS 上设置简单的 Haskell 开发环境？

4

1 回答 1

32

这是基于每个项目的一种方法。我正在开发一个 Yesod webbapp，所以我以我当前的设置为例。

在我的项目文件夹中，我有两个文件：（default.nix指定如何构建我的项目）和shell.nix（指定如何设置构建输入）。

这样我就可以运行nix-shell，它把我放到一个安装了 ghc 的环境中，并安装了提供的包和路径设置。

设置

默认.nix

{ stdenv, haskellPackages }:

let
  env = haskellPackages.ghcWithPackages (p: with p; [
    aeson
    bytestring
    cabal-install
    classy-prelude
    classy-prelude-conduit
    classy-prelude-yesod
    conduit
    containers
    data-default
    directory
    fast-logger
    file-embed
    hjsmin
    http-conduit
    monad-control
    monad-logger
    persistent
    persistent-postgresql
    persistent-template
    safe
    shakespeare
    template-haskell
    text
    time
    unordered-containers
    vector
    wai-extra
    wai-logger
    warp
    yaml
    yesod
    yesod-auth
    yesod-bin
    yesod-core
    yesod-form
    yesod-static
  ]);
in
  stdenv.mkDerivation {
    name        = "project-name";
    buildInputs = [env];
    shellHook   = ''
      export NIX_GHC="${env}/bin/ghc"
      export NIX_GHCPKG="${env}/bin/ghc-pkg"
      export NIX_GHC_DOCDIR="${env}/share/doc/ghc/html"
      export NIX_GHC_LIBDIR=$( $NIX_GHC --print-libdir )
    '';
  }

shell.nix

{ pkgs ? (import <nixpkgs> {}) }:

(import ./default.nix) {
    stdenv            = pkgs.stdenv;
    haskellPackages = pkgs.haskellPackages;
  }

更多信息

有关更多信息，您可以阅读：

Haskell NG 基础设施之旅：第一部分

Haskell NG 基础设施之旅：第二部分

这些链接解释了 haskell-ng 的工作原理以及将来会发生什么。

如果您想深入了解 haskell-ng 基础架构的来源，我建议：

定义 haskellPackages 的文件

haskell 包模块

haskell 模块文件夹

更新：在启用分析的情况下构建依赖项

haskell-ng 中的所有包都在hackage-packages.nix中定义。它们是使用cabal.mkDerivation.

如果你想覆盖一个包的构建方式，你需要覆盖mkDerivation这个包的调用方式。在 Haskell Wiki 中，您可以获得有关如何执行此操作的信息。. 基本上，您haskellPackages使用每个包所需的覆盖定义一个新的：

let haskellPackages' = haskellPackages.override {
       overrides = self: super: {
         fullstop = super.fullstop.override {
           mkDerivation = (attrs: self.mkDerivation (attrs // { doCheck = false; }));
         };
       };
     };

这可能会非常乏味，因此您可以使用文件lib.nix中的辅助函数。haskell-modules

该文件haskell-ng导入lib.nix并公开它。并且haskell-ng作为顶级包公开，因此您可以轻松访问 lib 函数。

假设我们有一个想要在文本库上启用分析的包，我们可以这样做：

{ pkgs ? (import <nixpkgs> {}).pkgs }:

let
  lib = pkgs.haskell-ng.lib;
  env = pkgs.haskellPackages.ghcWithPackages (p: with p; [
    (lib.enableLibraryProfiling text)
  ]);
in
  pkgs.stdenv.mkDerivation {
    name        = "hello-world-wide-web";
    buildInputs = [env];
    shellHook   = ''
      export NIX_GHC="${env}/bin/ghc"
      export NIX_GHCPKG="${env}/bin/ghc-pkg"
      export NIX_GHC_DOCDIR="${env}/share/doc/ghc/html"
      export NIX_GHC_LIBDIR=$( $NIX_GHC --print-libdir )
    '';
  }

这个周末我通过浏览haskell-ng 的nix 源并对其进行测试找到了这些信息。我对 NixOS 和 nix 还是很陌生，所以可能有更好的方法来做到这一点。

于 2015-03-13T13:33:45.430 回答