3

我回到探索 pegjs 并且显然还没有掌握核心概念。我正在尝试解析以谓词开头的“查询语言”，然后是操作数列表（可能包括另一个谓词）。所以一个简单的例子是：

OR(
   "string1"
   "string2"
)

我希望将上述内容转换为：

{
   predicate: "OR",
   operands: [
        {
           type: "STRING",
           value: "string1"
        },
        {
           type: "STRING",
           value: "string2"
        }
   ]
}

这个查询：

OR(
    "string1"
    "string2"
    AND (
        "string4"
        "string5"
    )
    "string3"
)

会变成这个 AST：

{
    predicate: "OR",
    operands: [
        {
            type: "STRING",
            value: "string1"
        },
        {
            type: "STRING",
            value: "string2"
        },
        {
            predicate: "AND"
            operands: [
                {
                    type: "STRING",
                    value: "string4"
                },
                {
                    type: "STRING",
                    value: "string5"
                }
            ]
        },
        {
            type: "STRING",
            value: "string3"
        }
    ] 
}

我的语法很接近，但有几个问题。这是当前的 PEGJS 语法。它可以直接粘贴到在线 pegjs 解析器 ( http://pegjs.majda.cz/online )。

start =
    or_predicate

or_predicate
  = ws* "OR" ws* "(" ws* operands:or_predicate ws* ")" ws* 
  { if(Array.isArray(operands)) {
      return {predicate: "OR", operands: operands} 
     } else {
      return {predicate: "OR", operands: [operands] }
     }
  }
  / and_predicate

and_predicate
  = ws* "AND" ws* "(" operands:and_predicate ")"
  { if(Array.isArray(operands)) {
      return {predicate: "AND", operands: operands} 
     } else {
      return {predicate: "AND", operands: [operands] }
     }
  }
  / operands  

operands
  = ws* values:operand+ { return values; }  

operand =
    string
    / ws or_predicate:or_predicate { return or_predicate; }

string =
   ws* "\"" value:valid_variable_characters "\"" 
   { return { type: "STRING", value: value.join("")}}

// List of valid characters for string variables
valid_variable_characters =
    [a-zA-Z0-9 _]+

ws =
   [ \t\n]

上面的语法处理了我给出的两个例子，但我注意到了两个问题，这导致我提出以下三个问题。

1.语法在这个看似简单的输入上失败（关键是嵌套的 OR 紧跟在父 OR 之后，“字符串”在末尾）：

OR(
   OR (
      "string1"
   )
   "string2"
)

我不确定是什么导致了这个或如何解决它。

2.语法目前有这条愚蠢的operand规则行：

operand =
    string
    / ws or_predicate:or_predicate { return or_predicate; }

请注意 . 之前第三行的前导空格 (ws) or_predicate。如果没有那个空格，我会收到错误“超出最大调用堆栈大小”。我认为这与左递归有关，但对此并不积极。理想情况下，我希望那里没有必需的“ws”，因此没有这样的空格的查询可以工作：

OR("string1"OR("string2")"string3")

现在你必须人为地添加一些额外的空格，如下所示：

OR("string1" OR("string2") "string3")

3.我完全错误地接近这个语法吗？这只是我尝试的第二个，第一个是基于 pegjs 算术示例，所以我意识到我可能完全错误，这可能就是我遇到这些问题的原因。

感谢您的协助和时间！

最好的祝福，

埃德

4

1 回答 1

6

我对 PEG 也很陌生，但是在主要查看示例而不是阅读文档之后，您就会掌握它。

尝试将您的版本与此版本进行比较：

start
  = ws* predicate:predicate ws* { return predicate; }

predicate
  = "OR" ws* "(" operands:operand+ ")"  { return { predicate: 'OR', operands: operands }; }
  / "AND" ws* "(" operands:operand+ ")" { return { predicate: 'AND', operands: operands }; }

operand
  = ws* predicate:predicate ws* { return predicate; }
  / ws* string:string ws* { return string; }

string
  = "\"" chars:valid_variable_characters+ "\"" { return { type: "STRING", value: chars.join("")}}

valid_variable_characters = [a-zA-Z0-9 _]
ws = [ \t\n]

空格是可选的。

OR("str1"OR("str2""str3"AND("str4""str5"))"str6")

给出：

{
   "predicate": "OR",
   "operands": [
      {
         "type": "STRING",
         "value": "str1"
      },
      {
         "predicate": "OR",
         "operands": [
            {
               "type": "STRING",
               "value": "str2"
            },
            {
               "type": "STRING",
               "value": "str3"
            },
            {
               "predicate": "AND",
               "operands": [
                  {
                     "type": "STRING",
                     "value": "str4"
                  },
                  {
                     "type": "STRING",
                     "value": "str5"
                  }
               ]
            }
         ]
      },
      {
         "type": "STRING",
         "value": "str6"
      }
   ]
}
于 2015-03-12T11:53:43.713 回答