3

我想计算列表中某个元素的出现次数，如果有，则谓词唯一性为真，否则为假。但是，如果元素出现不止一次，Prolog 会发现它是真的。我不知道该怎么办...

count([], X, 0).
count([X|T], X, Y) :- count(T, X, Z), Y is 1+Z, write(Z).
count([_|T], X, Z) :- count(T, X, Z).

unique(St, [Y|RestList]) :- count([Y|RestList], St, N), N =:= 1.
4

2 回答 2

4

只要第一个参数是一个基本列表，该解决方案就可以工作。在其他一些情况下，它是不正确的：

?- count([E], a, 0).
false.

在这里我们问

长度为 1 的列表的元素必须如何E看起来才能使列表包含 0 次出现a？

事实上，这个问题有答案，比如E = bor E = c：

?- count([b],a,0).
true.

?- count([c],a,0).
true.

因此，Prolog 的回答是不完整的。它应该说，是的。但是怎么做？

count([], _, 0).
count([E|Es], F, N0) :-
   count(Es, F, N1),
   if_(E = F, D = 1, D = 0),
   N0 is N1+D.

这使用if_/3和(=)/3。

?- length(Xs, I), count_dif(Xs, a, N).
   Xs = [],
   I = N, N = 0
;  Xs = [a],
   I = N, N = 1
;  Xs = [_A],
   I = 1,
   N = 0,
   dif(_A, a)
;  Xs = [a, a],
   I = N, N = 2
;  Xs = [_A, a],
   I = 2,
   N = 1,
   dif(_A, a) ;
   Xs = [a, _A],
   I = 2,
   N = 1,
   dif(_A, a) ;
   Xs = [_A, _B],
   I = 2,
   N = 0,
   dif(_A, a),
   dif(_B, a)
...

为了进一步改进这一点，我们可能会使用library(clpfd)SICStus、YAP 和 SWI 中提供的版本。

:- use_module(library(clpfd)).

count([], _, 0).
count([E|Es], F, N0) :-
   N0 #>= 0,
   if_(E = F, D = 1, D = 0),
   N0 #= N1+D,
   count(Es, F, N1).

现在甚至以下终止：

?- count([a,a|_], a, 1).
false.

?- N #< 2, count([a,a|_], a, N).
false.
于 2015-03-10T18:40:13.323 回答
1

使用您自己的子句，我只是对程序进行了一些优化：

  • 用匿名变量替换单例变量
  • 在计数谓词的第二个子句上添加一个cut
  • 删除唯一子句的第二个条件。

这是现在的程序：

count([],_,0).

count([X|T],X,Y):- !, count(T,X,Z), Y is 1+Z.

count([_|T],X,Z):- count(T,X,Z).

unique(St,L):- count(L,St,1).

咨询：

?- count([2,3,4,3], 3,N).
N = 2.

?- unique(3, [2,3,4,5]).
true.
于 2015-03-09T23:32:26.220 回答