2

我在 Oracle11g 中有下表。

SQL> DESC tmp_test;
Name                 Type          Nullable Default Comments 
-------------------- ------------- -------- ------- -------- 
SERNO                NUMBER(10)                              
CARDNO               VARCHAR2(25)  Y                         
COL_A                VARCHAR2(255) Y                         
DATEA                DATE          Y                         
DATEB                DATE          Y                         
TAG                  VARCHAR2(255) Y                         
FEEDBACK             CHAR(1)       Y


SQL> 
SQL> SELECT * FROM (SELECT T.COL_A FROM TEMP_TEST T ORDER BY DBMS_RANDOM.VALUE) WHERE ROWNUM <=10;
COL_A
--------------------------------------------------------------------------------
00 OK.20150301-0000
00 OK.20150301-0000
00 OK.20150301-0000
00 OK.20150205-0000
00 OK.20150301-0000
00 OK.20150301-0000
00 OK.20150213-0000
00 OK.20150301-0000
00 OK.20150129-0000
00 OK.20150301-0000
10 rows selected

SQL>

我正在尝试识别表 TEMP_TEST 中 COL_A 中的 DATE 小于 SYSDATE - 7 的所有行。

SQL>
SQL> SELECT * FROM TEMP_TEST T WHERE
TO_DATE(SUBSTR(TRIM(T.COL_A),7,8),'YYYYMMDD') < sysdate-7;
**ORA-01841: (full) year must be between -4713 and +9999, and not be 0**
SQL>

该表仅包含 200 行，因此我直观地检查了数据是否存在任何问题。所有日期均有效。这个错误的原因可能是什么？

谢谢

4

2 回答 2

2

显然所有日期都无效，因此您会遇到错误。我会尝试以下类似的方法（未经测试，但认为没问题），只是为了识别问题记录。

declare 
  v_date date;
begin
  for c in (select col_a from temp_test) loop
    begin
      v_date := to_date(substr(trim(c.col_a),7,8),'YYYYMMDD');
    exception when others then
      dbms_output.put_line(c.col_a);
    end;
  end loop;
end;

请注意，这种others用作唯一异常处理程序的做法通常被认为是不好的做法。在生产代码中，应单独处理异常。即使用于调试，最好输出 SQL 错误，但对于预期只有少数错误的第一次通过，有时只是懒惰也没关系。

于 2015-03-03T11:16:26.527 回答
2

使用显式游标来调试数字或日期转换错误通常会很快发现有问题的行（在这里，我伪造了您的 TEMP_TEST 表）：

declare
  cursor l_cur is
    with temp_test(col_a) as (
      select '20150201_abc' col_a from dual union all
      select 'x0150201_abc' col_a from dual union all
      select '20150201_abc' col_a from dual)      
    SELECT * FROM TEMP_TEST T;

  l_data l_cur%rowtype;
  dummy  date;
begin
  open l_cur;
  loop
    fetch l_cur
      into l_data;
    exit when l_cur%notfound;
    begin
      dummy := TO_DATE(SUBSTR(TRIM(l_data.COL_A), 1, 8), 'YYYYMMDD');
    exception
      when others then
        dbms_output.put_line(sqlerrm || ' for ' || l_data.col_a);
    end;
  end loop;
end;

编辑：WHEN OTHERS此处仅用于交互式调试目的 - 请不要在生产代码中使用它。

于 2015-03-03T11:20:55.470 回答