6

有没有办法通过从每个字符串列表中选择一个项目然后连接结果来在 FsCheck 中生成一个字符串？

我完全被卡住了，似乎无法弄清楚。我查看了文档和github 存储库中的类似内容。我已经从FSharpForFunAndProfit完成了我对 FsCheck 的大部分阅读。

这就像我想的那样：

let rand = System.Random()
let randInt max = rand.Next(0, max)

let selectLetter (string: string) = 
    let whichLettersIndex = String.length string |> randInt
    string.Substring(whichLettersIndex, 1)

let generateOddlySpelledWord listOfStrings = 
    List.map selectLetter listOfStrings
    |> String.concat ""

let usingGenerateOddlySpelledWord =
    generateOddlySpelledWord ["zZ"; "oO0Ò"; "eEê"]

这应该会产生类似“Z0ê”或“zÒE”的东西。

4

1 回答 1

6

这是做你想做的吗？

open FsCheck

let createGenerators (l : string seq) =
    l |> Seq.map Gen.elements |> Seq.toList

type OddlySpelledWords =
    static member String() =
        ["zZ"; "oO0Ò"; "eEê"]
        |> createGenerators
        |> Gen.sequence
        |> Gen.map (List.map string >> String.concat "")
        |> Arb.fromGen

临时测试：

open FsCheck.Xunit

[<Property(Arbitrary = [| typeof<OddlySpelledWords> |])>]
let test (s : string) =
    printfn "%s" s

输出（截断）：

  z0ê
  ZÒe
  ZOe
  zoê
  ZÒe
  zoê
  Z0e
  zoê
  z0ê
  ZOe
  zÒê
  z0E
  zoe

解释

该createGenerators函数具有类型seq string -> Gen<char> list，它使用Gen为每个字符串创建一个Gen.elements，因为字符串也是一个char seq; Gen.elements创建一个将从每个字符串Gen中选择其中一个值的值。char

然后它用于Gen.sequence将 转换Gen<char> list为Gen <char list>，然后从那里映射。

顺便说一句，您也可以内联createGenerators：

type OddlySpelledWords =
    static member String() =
        ["zZ"; "oO0Ò"; "eEê"]
        |> List.map Gen.elements
        |> Gen.sequence
        |> Gen.map (List.map string >> String.concat "")
        |> Arb.fromGen
于 2015-03-01T20:55:03.603 回答