vba - 获取连接器层

Question

我可以在 vba 中获取连接器分配到的层的名称吗？

我正在用这样的形状做这个

ActivePage.Shapes(1).layer(1)

现在我正在寻找类似的东西，但用于连接器。

Answer 1

我对您的问题并不完全清楚，但是连接器没有什么特别之处-它们仍然只是形状。因此，如果您知道目标形状和图层的索引，则可以使用上面的代码。

Visio 中的形状也可以属于多个图层（图层的工作方式与 Photoshop 不同），因此您可能需要先获取图层数，然后再遍历每个图层。例如：

Sub CheckLayers()
    Dim shp As Visio.Shape
    Dim i As Integer
    For Each shp In ActivePage.Shapes
        Debug.Print shp.NameU
        For i = 1 To shp.LayerCount
            Debug.Print "  " & shp.Layer(i).Name
        Next i
        Debug.Print ""
    Next shp
End Sub

此外，根据您要执行的操作，您可能希望利用Page.CreateSelection 方法来返回基于特定图层上的形状的选择。这是来自 Visio SDK 的略微修改的版本：

Public Sub CreateSelection_Layer_Example()

 Dim vsoLayer As Visio.Layer
 Dim vsoSelection As Visio.Selection

 Set vsoLayer = ActivePage.Layers.ItemU("Connector")
 Set vsoSelection = ActivePage.CreateSelection(visSelTypeByLayer, visSelModeSkipSuper, vsoLayer)

 'Note that you don't have to pass the selection object to
 'the ActiveWindow Selection property - you can just work
 'with it directly if you want to
 Application.ActiveWindow.Selection = vsoSelection

End Sub

如果您使用的是动态连接器，它会自动分配给一个名为“连接器”的层。