windows - HTML 的输入 type="password" 的 Windows 批处理等效项是什么？

Question

我需要从 Windows 脚本中的用户那里获取身份验证凭据，但是经典的“第一个 Google 结果”方法：

SET /P USR=Username: 
SET /P PWD=Password:

不太令人满意，所以我想知道是否可以说HTML 的输入 type="password" 的“等价物”？

任何评论将不胜感激，在此先感谢！

score 5 · Accepted Answer

看看这个

http://www.netikka.net/tsneti/info/tscmd052.htm

@echo off & setlocal enableextensions
    :: Build a Visual Basic Script
    set vbs_=%temp%\tmp$$$.vbs
    set skip=
    findstr "'%skip%VBS" "%~f0" > "%vbs_%"
    ::
    :: Prompting without linefeed as in Item #15
    echo.|set /p="Password: "

    :: Run the script with Microsoft Windows Script Host Version 5.6
    for /f "tokens=* delims=" %%a in ('cscript //nologo "%vbs_%"') do set MyPass1=%%a

    ::
    ::echo.
    echo.|set /p="Retype  : "

    for /f "tokens=* delims=" %%a in ('cscript //nologo "%vbs_%"') do set MyPass2=%%a
    ::

    :: Clean up
    for %%f in ("%vbs_%") do if exist %%f del %%f
    ::
    :: Demonstrate the result
    echo.
    if "%MyPass1%"=="%MyPass2%" (
      echo The entered password was %MyPass1%
      ) else (
      echo No match)
    endlocal & goto :EOF
    '
    'The Visual Basic Script
    Set WshPass = WScript.CreateObject("ScriptPW.Password") 'VBS
    Password=WshPass.GetPassWord() 'VBS
    WScript.Echo PassWord 'VBS

score 4 · Accepted Answer

通过明智地使用 Windows 上免费提供的另一种工具，以下两个脚本可以完成您想要的工作。

首先，GetPwd.cmd：

@echo off
:: GetPwd.cmd - Get password with no echo.
<nul: set /p passwd=Password: 
for /f "delims=" %%i in ('cscript /nologo GetPwd.vbs') do set passwd=%%i
echo.
:: This bit's just to prove we have the password.
echo %passwd%

然后，GetPwd.vbs：

' GetPwd.vbs - Get password with no echo then echo it. '
Set oScriptPW = CreateObject("ScriptPW.Password")
strPassword = oScriptPW.GetPassword()
Wscript.StdOut.WriteLine strPassword

解释：

GetPwd.vbs 只是使用密码对象从用户那里输入密码，然后将其打印到标准输出（下一段将解释为什么在终端中没有显示）。

GetPwd.cmd 有点棘手（但通常是命令脚本）。

该"<nul: set /p passwd=Password: "命令仅输出没有尾随 CR/LF 的提示 - 这是模拟 bash 的一种偷偷摸摸的方式"echo -n"。passwd作为副作用，它设置为空字符串并且不等待输入，因为它从 nul: 设备获取输入。

该"for /f "delims=" %%i in ('cscript /nologo GetPwd.vbs') do set passwd=%%i"声明是最棘手的部分。它在没有 Microsoft 广告 ( /nologo) 的情况下运行 vbscript，因此唯一的行输出是密码（来自 vbscript "Wscript.StdOut.WriteLine strPassword".

将分隔符设置为空需要捕获带有空格的输入行，否则您只会得到第一个单词。"for ... do set ..."设置passwd为从 vbscript 输出的实际密码。

然后我们回显一个空行（实际上是终止该"Password: "行）并回显密码，以便您验证它是否有效：

C:\Pax> GetPwd
Password:
this is my password

C:\Pax>

scriptpw.dll 可用于 XP 和 2K3，但不一定是更高版本。

Vista和大概Win7的说明如下，试一试：

为了屏蔽密码，脚本利用了 ScriptPW COM 对象。ScriptPW 在 Windows XP 和 Windows 2003 上默认加载。如果您运行的是 Windows 2000 或 Windows Vista，则需要将scriptpw.dll文件从Windows\System32XP 系统或 Windows 2003 系统的文件夹复制到 Windows 2000 上的Winnt\System32或文件夹Windows\System32或 Vista 系统。复制 DLL 后，您需要通过运行以下命令来注册它：

regsvr32 scriptpw.dll

要在 Vista 机器上成功注册 DLL，您需要以管理员身份打开命令提示符。为此，请单击开始 | 所有程序 | 配件。然后右键单击命令提示符快捷方式并选择“以管理员身份运行”。以管理员身份进入命令提示符后，您将能够成功运行regsvr32 scriptpw.dll命令以注册 DLL。

score 2 · Accepted Answer

1.纯批处理解决方案，（ab）使用XCOPY命令及其在此处/P /L找到的开关：

:: Hidden.cmd
::Tom Lavedas, 02/05/2013, 02/20/2013
::Carlos, 02/22/2013
::https://groups.google.com/forum/#!topic/alt.msdos.batch.nt/f7mb_f99lYI


@Echo Off
:HInput
SetLocal EnableExtensions EnableDelayedExpansion
Set "FILE=%Temp%.\T"
Set "FILE=.\T"
Keys List >"%File%"
Set /P "=Hidden text ending with Ctrl-C?: " <Nul
Echo.
Set "HInput="
:HInput_
For /F "tokens=1* delims=?" %%A In (
 '"Xcopy /P /L "%FILE%" "%FILE%" 2>Nul"'
) Do (
  Set "Text=%%B"
  If Defined Text (
    Set "Char=!Text:~1,1!"
    Set "Intro=1"
    For /F delims^=^ eol^= %%Z in ("!Char!") Do Set "Intro=0"
    Rem If press Intro
    If 1 Equ !Intro! Goto :HInput#
    Set "HInput=!HInput!!Char!"
  )
)
Goto :HInput_
:HInput#
Echo(!HInput!
Goto :Eof

2.使用HTA弹窗的密码提交者 。这是一个 .bat/jscript/mshta 混合文件，应保存为 .bat：

<!-- :
:: PasswordSubmitter.bat
@echo off
for /f "tokens=* delims=" %%p in ('mshta.exe "%~f0"') do (
    set "pass=%%p"
)

echo your password is %pass%
exit /b
-->

<html>
<head><title>Password submitter</title></head>
<body>

    <script language='javascript' >
        function pipePass() {
            var pass=document.getElementById('pass').value;
            var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);
            close(fso.Write(pass));

        }
    </script>

    <input type='password' name='pass' size='15'></input>
    <hr>
    <button onclick='pipePass()'>Submit</button>

</body>
</html>

3.自编译的 .net 混合.Again 应另存为.bat。与其他解决方案不同，它将创建/编译一个小的 .exe 文件，该文件将被调用（如果您希望可以删除它）。还需要安装 .net 框架，但这不是问题：

@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal

for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
   set "jsc=%%v"
)

if not exist "%~n0.exe" (
    "%jsc%" /nologo /out:"%~n0.exe" "%~dpsfnx0"
)

for /f "tokens=* delims=" %%p in ('"%~n0.exe"') do (
    set "pass=%%p"
)

echo your password is %pass%

endlocal & exit /b %errorlevel%

*/



import System;



var pwd = "";
var key;

Console.Error.Write("Enter password: ");

        do {
           key = Console.ReadKey(true);
           if ( (key.KeyChar.ToString().charCodeAt(0)) >= 20 && (key.KeyChar.ToString().charCodeAt(0) <= 126) ) {
              pwd=pwd+(key.KeyChar.ToString());
              Console.Error.Write("*");
           }   

        } while (key.Key != ConsoleKey.Enter);
        Console.Error.WriteLine();
        Console.WriteLine(pwd);

score 1 · Accepted Answer

我假设您不想在屏幕上回显密码。

如果弹出窗口对您来说没问题，您可以使用例如 VBScript 来显示一个显示密码字段的 IE 窗口。这是一个例子。

作为替代方案，您可以从 HTA（HTML 应用程序）文件调用您的脚本（请参阅HTML 应用程序简介 (HTA)。

问候，迪沃

score 1 · Accepted Answer

如果你可以安装 Cygwin，默认情况下你会得到一个 bash shell，所以这个命令可以工作：

读取 -s -p "密码：" PASSWORD

唯一的问题是现在 PASSWORD 的值仅在 bash shell 中设置，而不是作为批处理文件可以看到的环境变量（不要使用 PWD，因为这在 cygwin 中意味着其他东西）。因此，您必须将脚本重写为 bash shell 脚本（考虑到命令提示符的限制，可能不会太难！）。

或者您可以将密码从 cygwin 传递到批处理脚本，但这意味着运行命令提示符的新实例：

cmd /cyourbatchfile.bat $PASSWORD

有点令人费解，一点也不令人满意；）

score 1 · Accepted Answer

我们一直在做这样的事情，但是将密码放在命令行中并将其传递给批处理文件中的变量。

score 0 · Accepted Answer

另一种方法是从您的脚本中调用PowerShell命令。Batch下面是一个配置服务登录帐户的示例：

$password = Read-Host "Enter password" -AsSecureString;
$decodedpassword = [System.Runtime.InteropServices.Marshal]::PtrToStringAuto([System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($password));
& "sc.exe" config THE_SERVICE_NAME obj= THE_ACCOUNT password= $decodedPassword;

其中 THE_SERVICE_NAME 是要配置的服务的名称，THE_ACCOUNT 是登录帐户。

然后我们可以像这样从批处理脚本中使用它：

call powershell -Command "$password = Read-Host "Enter password" -AsSecureString; $decodedpassword = [System.Runtime.InteropServices.Marshal]::PtrToStringAuto([System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($password)); & "sc.exe" config THE_SERVICE_NAME obj= THE_ACCOUNT password= $decodedPassword;"

这只是调用 PowerShell.exe 并传递三个命令。

这种方法的优点是当今大多数 Windows 安装都包括PowerShell.，因此不需要额外的程序或脚本。缺点是您需要在PowerShell调用中使用密码（如在我的示例中）或将其存储在环境变量中，然后从批处理脚本中使用它。我更喜欢前者，因为它更安全、更简单。

score 0 · Accepted Answer

您可以将 ReadFormattedLine 子例程用于所有类型的格式化输入。例如，以下命令读取每个 8 个字符的用户名和密码，在屏幕上显示星号，无需按 Enter 即可自动继续：

call :ReadFormattedLine USR="********" /M "Username: "
call :ReadFormattedLine PWD="********" /M "Password: "

或者以不同的方式：

call :ReadFormattedLine nameAndPass="******** / ********" /M "Enter Username / Password: "

在前面的例子中，当用户完成用户名时，子程序显示斜线并读取密码；如果用户删除字符，斜线也会被自动删除。

这个子程序是用纯 Batch 编写的，所以它不需要任何额外的程序，并且它允许多种格式化输入操作，比如读取数字、将字母转换为大写等。您可以从 ReadFormattedLine 子程序下载Read a line with specific format。

score 0 · Accepted Answer

ConSet是由 Frank P. Westlake 编写的免费工具。它是标准 Windows 命令集的扩展版本。

ConSet.exe - 显示、设置或删除 cmd.exe 环境变量，修改控制台参数，并执行浮点数学运算。

由于它不是标准的 Windows 控制台应用程序，因此使用此工具需要将该工具与批处理文件一起分发，或者该工具存储在服务器共享上，并且批处理文件直接从服务器共享调用该工具。

ConSet很容易提示输入密码字符串，其中隐藏输入分配给环境变量：

ConSet.exe /PH "PWD=Password: "

附加参数H会导致隐藏用户输入。

score 0 · Accepted Answer

我编写了一个名为的开源工具editenv来替换我的旧editv32/editv64实用程序：

https://github.com/Bill-Stewart/editenv

它提供了--maskinput( -m) 选项[*]，可让您隐藏键入的输入。例子：

editenv --maskinput --prompt="Password: " PWD

此命令会显示一个Password:提示，并且您输入的任何内容都会放在PWD环境变量中。

在这里下载：

https://github.com/Bill-Stewart/editenv/releases

[*] 注意--maskinput( -m) 选项不安全——键入的输入以纯文本形式放置在环境中。此功能仅为方便起见。

windows - HTML 的输入 type="password" 的 Windows 批处理等效项是什么？

10 回答 10

Related

Reference