7

Embarcadero 的 TTaskbar 存在内存泄漏。由于我在表单上删除了此控件，因此每次关闭应用程序时，FastMM 都会报告泄漏。

我尝试使用以下代码使 FastMM 静音：

procedure TMainForm.FormCreate(Sender: TObject);
begin
 fastmm4.RegisterExpectedMemoryLeak(Taskbar);
end;

但它不会工作。如何注册此泄漏？

内存块已泄漏。尺寸为：100

此块由线程 0xC64 分配，当时的堆栈跟踪（返回地址）为：406A52 409A7B 409CAC 4283A0

[System.SysUtils][System][System.SysUtils.FmtStr] 409CC6 40D775 7628A65F
[Unknown function at StretchDIBits] 7731594E
[RtlpNtMakeTemporaryKey 处的
未知函数] 7731594E [RtlpNtMakeTemporaryKey 处的未知函数] 773168F8
[RtlpNtMakeTemporaryKey 处的未知函数] 773168DC [RtlpNtMakeTemporaryKey 处的
未知函数]

该块当前用于类对象：UnicodeString
分配号为：2209

内存块已泄漏。尺寸为：36

该块由线程 0xC64 分配，当时的堆栈跟踪（返回地址）为：406A52 407D43 40846A 42CD40
[System.SysUtils][System][System.SysUtils.Exception.CreateFmt] 5DEDD7
[System.Win.TaskbarCore] [System.Win][System.Win.TaskbarCore.TTaskbarBase.UpdateTab] 610F00
[Vcl.Taskbar][Vcl][Vcl.Taskbar.CheckMDI] 5DF39F
[System.Win.TaskbarCore][System.Win][System.Win. TaskbarCore.TTaskbarBase.ApplyTabsChanges] 610DB8
[Vcl.Taskbar][Vcl][Vcl.Taskbar.TCustomTaskbar.Initialize] 5EB044
[Vcl.Forms][Vcl][Vcl.Forms.TApplication.Run] 62573A
[MinimalTemplate.dpr][MinimalTemplate ][最小模板.最小模板][26]

该块当前用于类对象：ETaskbarException
分配编号为：2207

此应用程序已泄漏内存。小块泄漏是（不包括指针注册的预期泄漏）：

21 - 36 字节：ETaskbarException x 1
85 - 100 字节：UnicodeString x 1
[Vcl.Forms][Vcl][Vcl.Forms.TCustomForm.SetVisible] 5F5010

4

1 回答 1

10

此代码中的内存从以下位置泄漏System.Win.TaskbarCore：

procedure TTaskbarBase.UpdateTab;
var
  LpfIsiconic: LONGBOOL;
  LHandle: HWND;
  LFlags: Integer;
begin
  if FTaskbarIsAvailable then
  begin
    LHandle := GetFormHandle;
    if not FRegistered and TaskBar.RegisterTab(LHandle) then
    begin
      TaskBar.SetTabOrder(LHandle);
      TaskBar.SetTabActive(LHandle);
      FRegistered := True;
    end
    else
      ETaskbarException.CreateFmt(SCouldNotRegisterTabException, [TaskBar.LastError]);
....

最后一行创建了一个异常，然后什么也不做。异常及其拥有的字符串被泄露。据 FastMM 报道。

如果您可以获得它们的地址，您可以将这些对象注册为被泄露。但是，您不能这样做。没有办法引用这个异常对象。

如果您只是必须避免这种错误报告的泄漏，并且这样做是有道理的，那么您需要System.Win.TaskbarCore在项目中包含一个固定版本的 。制作该文件的副本，并将其添加到您的项目中。然后修改代码修复故障。我的猜测是它会是这样的：

if not FRegistered then
begin
  if TaskBar.RegisterTab(LHandle) then
  begin
    TaskBar.SetTabOrder(LHandle);
    TaskBar.SetTabActive(LHandle);
    FRegistered := True;
  end
  else
    raise ETaskbarException.CreateFmt(SCouldNotRegisterTabException, [TaskBar.LastError]);
end;

显然，这需要向 Embarcadero 报告。我建议你提交一个错误报告。

解决此问题的另一种方法是尝试完全避免执行虚假行。我相信，如果您从 .dfm 文件中删除此行，则应避免使用虚假行，从而避免泄漏：

Visible = True

只需删除该行，它似乎是触发器。

请注意，我通过将项目削减到其基本框架来解决这个问题。为了重现问题，这是所需的最小 dfm 文件：

object Form1: TMainForm
  Visible = True
  object Taskbar1: TTaskbar
  end
end

有了这个 dfm 文件，就没有泄漏：

object Form1: TMainForm
  object Taskbar1: TTaskbar
  end
end

通过将项目缩减到最低限度，我能够找到触发器。我怎么强调这种最小化复制技术的价值都不为过。

感谢 Remy 找到此故障的 QC 报告：QC#128865

于 2015-02-19T12:28:49.107 回答