0

我正在尝试为我遇到的以下问题找到一个 xslt 解决方案。

我想找到一组共享节点名称和属性但具有不同值的 3 个后续行。输入中的第一行包含一个标识符，第二行和第三行包含来自源系统的值。我想找到第二行和第三行具有不同值的集合。

例如

<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">78923</eba7:mi235>
<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">1111</eba7:mi235>
<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">2222</eba7:mi235>

也可能存在仅具有标识符的行集、具有标识符的行集和仅具有来自源系统的值的行或第二行和第三行具有相同值的行集。

例如

<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x24-x195-x10-x4">78748</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x24-x195-x10-x4">0</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">78804</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">12345</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">12345</eba7:mi310>

这些我不想在输出中找到。

我要创建的输出是

<eba7:mi235 id="78923" value1="1111" value2="2222" />

输入的结构使得行总是这样排序。所以我尝试使用位置访问它们，但这没有用。

有人能指出我正确的方向吗？使用位置是否正确？

我附上了一个带有下面输入数据的文件

谢谢。

保罗。

<?xml version="1.0" encoding="utf-8"?>
<xbrl xml:lang="en" xmlns="http://www.xbrl.org/2003/instance" xmlns:eba7="http://www.eba.europa.eu/xbrl/crr/dict/met" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:link="http://www.xbrl.org/2003/linkbase">
<link:schemaRef xlink:type="simple" xlink:href="http://www.eba.europa.eu/eu/fr/xbrl/crr/fws/corep/its-2013-02/2014-07-31/mod/corep_con.xsd" />
<context id="I-2014-E">
<entity>
  <identifier scheme="http://www.dnb.nl/id">578</identifier>
</entity>
<period>
  <instant>2014-12-31</instant>
</period>
</context>  
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x24-x195-x10-x4">78748</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x24-x195-x10-x4">0</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">78804</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">12345</eba7:mi310>
<eba7:mi310 contextRef="I-2014-E-dim-x42-x9-x25-x195-x10-x4">12345</eba7:mi310>
<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">78923</eba7:mi235>
<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">1111</eba7:mi235>
<eba7:mi235 contextRef="I-2014-E-dim-x43-x9-x156-x51-x14">2222</eba7:mi235>
</xbrl>
4

2 回答 2

2

我认为这个问题的定义不够好。它可以用几种方式来解释。

如果我们假设您想要：

  1. 基于标签名称和@contextRef 值相同的所有给定元素分组；元素的相互位置与此目的无关；

  2. 计算每组中不同的值；如果有三个或更多，则将具有公共标记名称的元素写入输出，并为该组中的每个不同值添加编号属性；

那么最好做类似的事情：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xbrli="http://www.xbrl.org/2003/instance" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="k1" match="*" use="concat(name(), '|', @contextRef)"/>
<xsl:key name="k2" match="*" use="concat(name(), '|', @contextRef, '|', .)"/>

<xsl:template match="/xbrli:xbrl">
    <xsl:copy>
        <xsl:for-each select="*[count(.|key('k1', concat(name(), '|', @contextRef))[1])=1]">
            <xsl:variable name="distinct-values" select="key('k1', concat(name(), '|', @contextRef)) [count(.|key('k2', concat(name(), '|', @contextRef, '|', .))[1])=1]"/>
            <xsl:if test="count($distinct-values) &gt;= 3">
                <xsl:copy>
                    <xsl:for-each select="$distinct-values">
                        <xsl:attribute name="value{position()}">
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                    </xsl:for-each>
                </xsl:copy>
            </xsl:if>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

应用于以下格式良好的测试输入：

<xbrl xmlns="http://www.xbrl.org/2003/instance" xmlns:eba7="http://www.eba.europa.eu/xbrl/crr/dict/met">
    <eba7:a contextRef="x">11</eba7:a>
    <eba7:a contextRef="x">12</eba7:a>

    <eba7:a contextRef="y">21</eba7:a>
    <eba7:a contextRef="y">22</eba7:a>
    <eba7:a contextRef="y">23</eba7:a>

    <eba7:b contextRef="x">31</eba7:b>
    <eba7:b contextRef="x">32</eba7:b>
    <eba7:b contextRef="x">33</eba7:b>
    <eba7:b contextRef="x">33</eba7:b>

    <eba7:c contextRef="x">41</eba7:c>
    <eba7:c contextRef="x">41</eba7:c>
    <eba7:c contextRef="x">42</eba7:c>
    <eba7:c contextRef="x">42</eba7:c>
</xbrl>

结果将是：

<?xml version="1.0" encoding="utf-8"?>
<xbrl xmlns="http://www.xbrl.org/2003/instance" xmlns:eba7="http://www.eba.europa.eu/xbrl/crr/dict/met">
   <eba7:a value1="21" value2="22" value3="23"/>
   <eba7:b value1="31" value2="32" value3="33"/>
</xbrl>

注意：

  1. 您必须熟悉Muenchian 分组方法才能理解这一点；

  2. 编号属性不是良好的 XML 实践。我建议您（或当权者）重新考虑这一要求。

于 2015-02-15T17:57:33.527 回答
1

此样式表是否可以解决您的问题：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  xmlns:xbrli="http://www.xbrl.org/2003/instance" version="1.0">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
<xsl:strip-space elements="*"/>

<xsl:key name="elements" match="*" use="@contextRef"/>

<xsl:template match="/xbrli:xbrl">
    <xsl:copy>
        <xsl:apply-templates select="*[@contextRef
                                        and count(key('elements', @contextRef)) = 3 
                                        and key('elements', @contextRef)[2] != key('elements', @contextRef)[3]
                                        and count(. | key('elements', @contextRef)[1]) = 1]"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*">
    <xsl:copy>
        <xsl:attribute name="id">
            <xsl:value-of select="."/>
        </xsl:attribute>
        <xsl:attribute name="value1">
            <xsl:value-of select="key('elements', @contextRef)[2]"/>
        </xsl:attribute>
        <xsl:attribute name="value2">
            <xsl:value-of select="key('elements', @contextRef)[3]"/>
        </xsl:attribute>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

在这里，akey被声明为匹配@contextRef作为标识符的元素。第一个模板将模板应用于具有唯一性的第一个元素@contextRef（以及那些与其他条件匹配的元素，例如总元素@contextRef必须为 3，并且第二个和第三个元素的值不能相同）。

下一个模板匹配这些元素（来自第一个模板），并创建进一步的输出。

于 2015-02-15T12:10:48.183 回答