0

在尝试用 groovy 中的闭包重新发明 if/else 语法时，我无法让它工作。我认为在括号外放置多个闭包是不允许的，但它可能是别的东西。

如果不允许，您将如何重现 if/else 语法？这是一个思想实验，所以不要告诉我这个实现的效率低下。

我的代码：

void ifx(boolean condition, Closure action){
  ["${true.toString()}": action].get(condition.toString(), {})()
}

void ifx(boolean condition, Closure action, Closure elsex){
  ["${true.toString()}": action, "${false.toString()}": elsex].get(condition.toString())()
}

void elsex(Closure action){
    action()
}

ifx(1==2){
    println("1")
} ifx(1==3){
    println("2")
} elsex{
    println("3")
}

错误信息：

java.lang.NullPointerException：无法在空对象上调用方法 ifx()

4

2 回答 2

2

沿着这些思路工作：

更新了闭包以避免全局状态：

def ifx( outerCondition, outerBlock ) {
  boolean matched = false
  def realIfx
  realIfx = { condition, block ->
    if (condition) {
      matched = true
      block()
    }
    [ifx: realIfx, elsex: { elseBlock -> if(!matched) elseBlock() }]
  }

  realIfx outerCondition, outerBlock
}

和一些测试：

def result

ifx(1 == 2) {
  result = 1
} ifx(1 == 3) {
  result = 2
} elsex {
  result = 3
}

assert result == 3
result = null


ifx (1 == 2) {
  result = 1
} ifx (2 == 2) {
  result = 2
} elsex {
  result = 3
}

assert result == 2
result = null

ifx (true) {
  result = 1
} ifx (2 == 1) {
  result = 2
} elsex {
  result = 3
}

assert result == 1
于 2015-02-13T13:19:42.680 回答
1

ifx (1==2) {} ifx(1==3) {} elsex {}是转换为的命令链表达式ifx(1==2,{}).ifx(1==3,{}).elsex({})。由于 void 转换为 null，因此应该清楚第二个 ifx 调用随后会因 NPE 而失败。为了实现 if/else 之类的事情，我可能会做以下事情

void ifx(boolean condition, Closure ifBlock, Closure elseBlock) {
 ....
}
ifx (1==2) {...}{...}

意味着根本不使用 else 关键字。如果你想保持你的想法，你必须返回一些你可以调用 elsex 和 ifx 的东西。或者如果不是 ifx，那么在第一个 ifx 之后添加一个换行符

于 2015-02-13T12:45:22.320 回答