2

所以我有一个 Liquidsoap 实例，我用它来流式传输到 Icecast 服务器。

我想录制任何自动发生的直播，我现在正在做并且运行良好。

我想做的是在创建 mp3 档案时使用现场表演的元数据（特别是歌曲名）。

                #!/usr/local/bin/liquidsoap

            set("log.file",true)
            set("log.file.path","/var/log/liquidsoap/radiostation.log")
            set("log.stdout",true)
            set("log.level",3)
            #-------------------------------------

            set("harbor.bind_addr","0.0.0.0")

            #-------------------------------------

            backup_playlist = playlist("/home/radio/playlists/playlist.pls",conservative=true,reload_mode="watch")
            output.dummy(fallible=true,backup_playlist)

            #-------------------------------------

            live_dj = input.harbor(id="live",port=9000,password="XXX", "live")

            date = '%m-%d-%Y'
            time = '%H:%M:%S'
            output.file(%mp3, "/var/www/recorded-shows/#{Title} - Recorded On #{date} At #{time}.mp3", live_dj, fallible=true)

            #time_stamp = '%m-%d-%Y, %H:%M:%S'
            #output.file(%mp3, "/var/www/recorded-shows/live_dj_#{time_stamp}.mp3", live_dj, fallible=true)

            #-------------------------------------

            on_fail = single("/home/radio/fallback/Enei -The Moment Feat DRS.mp3")

            #-------------------------------------

            source = fallback(track_sensitive=false,
                              [live_dj, backup_playlist, on_fail])

            # We output the stream to icecast
            output.icecast(%mp3,id="icecast",
                           mount="myradio.mp3",
                           host="localhost", password="XXX",
                           icy_metadata="true",description="cool radio",
                           url="http://myradio.fm",
                           source)

我已经添加了#{title}，我希望我的歌曲标题出现，但遗憾的是我无法得到这个填充。

我的 Dj 使用 BUTT 并且节目标题作为他们连接的一部分连接，因此数据应该在预录制时可用。

非常感谢任何建议！

4

1 回答 1

0

这远不像看起来那么容易。

  1. 元数据是动态的title，因此在脚本初始化时不能作为变量使用
  2. output.file脚本初始化时编译文件名参数

解决方案包括：

  1. 定义变量引用title以填充实时元数据
  2. 输出到临时文件
  3. on_close使用with 参数在关闭时重命名文件output.file（在这种情况下，我们可以只在标题前添加）

这将给出以下代码（在 Linux 机器上，在 Windows 上更改mv为ren）：

date = '%m-%d-%Y'
time = '%H:%M:%S'
# Title is a reference
title = ref ""

# Populate with metadata
def get_title(m)
  title := m['title']
end
live_dj = on_metadata(get_title,live_dj)

# Rename file on close
def on_close(filename)
  # Generate new file name
  new_filename = "#{path.dirname(filename)}/#{!title} - #{basename(filename)}"
  # Rename file
  system("mv '#{filename}' '#{new_filename}'")
end

output.file(on_close=on_close, %mp3, "/var/www/recorded-shows/Recorded On #{date} At #{time}.mp3", live_dj, fallible=true)

我测试了一个类似的场景，它工作得很好。请注意，每次 DJ 断开连接或更新标题时，这都会创建一个新文件。另请记住，时间戳将由output.file.

这基于来自 Liquidsoap 开发人员的以下示例：https ://github.com/savonet/liquidsoap/issues/661#issuecomment-439935854 ）

于 2020-03-10T01:03:48.773 回答