3

我知道我可以在 erlang 中将 seq_trace 设置为正在执行的当前进程。但是如何从 shell 或远程 shell （如 dbg tracking）将其设置在另一个进程上？

4

1 回答 1

3

您可以使用 对另一个进程启用顺序跟踪dbg。例如，假设我们有一个x带有导出call/2函数的模块：

call(Pid, Msg) ->
    Pid ! {self(), Msg},
    receive      
        {Pid, Reply} -> Reply
    end.

这个函数实现了一个简单的调用响应。假设我们有一个y具有循环接收器功能的模块：

loop() ->
    receive
        {Pid, Msg} ->
            seq_trace:print({?MODULE, self(), Pid, Msg}),
            Pid ! {self(), {Msg, os:timestamp()}};
        _ -> ok
    end,
    ?MODULE:loop().

这个函数需要一个由 发送的消息x:call/2，当它收到一个消息时，它会在顺序跟踪中打印一条消息（如果启用），然后将原始消息发送回给调用者，并加上时间戳。它忽略所有其他消息。

我们还需要一个函数来收集顺序跟踪。下面的递归systracer/1函数只是将元组收集seq_trace到一个列表中，并seq_trace在被询问时生成消息列表：

systracer(Acc) ->
    receive
        {seq_trace,_,_,_}=S ->
            systracer([S|Acc]);
        {seq_trace,_,_}=S ->
            systracer([S|Acc]);
        {dump, Pid} ->
            Pid ! lists:reverse(Acc),
            systracer([]);
        stop -> ok
    end.

假设我们的systracer/1函数也是从模块中导出的x。

让我们使用我们的 Erlang shell 来设置这一切。首先，让我们生成y:loop/0and x:systracer/1：

1> Y = spawn(y,loop,[]).
<0.36.0>
2> S = spawn(x,systracer,[[]]).
<0.38.0>
3> seq_trace:set_system_tracer(S).
false

生成后x:systracer/1，我们将进程设置为seq_trace系统跟踪器。现在我们需要开始dbg：

4> dbg:tracer(), dbg:p(all,call).
{ok,[{matched,nonode@nohost,28}]}

这些dbg调用非常标准，但您可以根据需要随意更改它们，特别是如果您计划dbg在调试会话期间使用跟踪。

实际上，当您使用 启用顺序跟踪时dbg，通常通过键入函数的特定参数来实现。这使您能够获取特定于给定函数调用的跟踪，而无需获取该函数的所有调用的跟踪。沿着这些思路，我们将在使用具有 atom 值的第二个参数调用dbg:tpl/3时打开顺序跟踪标志。首先，我们使用创建适当的匹配规范来启用我们想要的顺序跟踪标志，然后我们将应用匹配规范：x:call/2tracedbg:fun2ms/1dbg:tpl/3

5> Ms = dbg:fun2ms(fun([_,trace]) -> set_seq_token(send,true), set_seq_token('receive',true), set_seq_token(print,true) end).
[{['_',trace],
  [],
  [{set_seq_token,send,true},
   {set_seq_token,'receive',true},
   {set_seq_token,print,true}]}]
6> dbg:tpl(x,call,Ms).
{ok,[{matched,nonode@nohost,1},{saved,1}]}

现在我们可以x:call/2使用第二个参数调用trace以导致发生顺序跟踪。我们从一个衍生的进程中进行此调用，以避免在结果跟踪中出现与 shell I/O 相关的消息：

7> spawn(fun() -> x:call(Y, trace), x:call(Y, foo) end).
(<0.46.0>) call x:call(<0.36.0>,trace)
<0.46.0>

正如我们之前指定的，第一行输出来自正常dbg跟踪dbg:p(all, call)。要获得顺序跟踪结果，我们需要从我们的systrace/1进程中获取转储：

8> S ! {dump, self()}.
{dump,<0.34.0>}

这会将到目前为止收集的所有顺序跟踪发送到我们的 shell 进程。我们可以使用 shellflush()命令来查看它们：

9> flush().
Shell got [{seq_trace,0,{send,{0,1},<0.47.0>,<0.36.0>,{<0.47.0>,trace}}},
           {seq_trace,0,{'receive',{0,1},<0.47.0>,<0.36.0>,{<0.47.0>,trace}}},
           {seq_trace,0,{print,{1,2},<0.36.0>,[],{y,<0.36.0>,<0.47.0>,trace}}},
           {seq_trace,0,
                      {send,{1,3},
                            <0.36.0>,<0.47.0>,
                            {<0.36.0>,{trace,{1423,709096,206121}}}}},
           {seq_trace,0,
                      {'receive',{1,3},
                                 <0.36.0>,<0.47.0>,
                                 {<0.36.0>,{trace,{1423,709096,206121}}}}},
           {seq_trace,0,{send,{3,4},<0.47.0>,<0.36.0>,{<0.47.0>,foo}}},
           {seq_trace,0,{'receive',{3,4},<0.47.0>,<0.36.0>,{<0.47.0>,foo}}},
           {seq_trace,0,{print,{4,5},<0.36.0>,[],{y,<0.36.0>,<0.47.0>,foo}}},
           {seq_trace,0,
                      {send,{4,6},
                            <0.36.0>,<0.47.0>,
                            {<0.36.0>,{foo,{1423,709096,206322}}}}},
           {seq_trace,0,
                      {'receive',{4,6},
                                 <0.36.0>,<0.47.0>,
                                 {<0.36.0>,{foo,{1423,709096,206322}}}}}]

果然，这些是我们期望看到的顺序跟踪消息。首先，对于包含trace原子的消息，我们有 send from，x:call/2然后是接收 iny:loop/0和 的结果seq_trace:print/1，然后是 send fromy:loop/0返回给 的调用者x:call/2。然后，由于x:call(Y,foo)在同一进程中调用，这意味着所有顺序跟踪标志仍然启用，第一组顺序跟踪消息后面是类似的x:call(Y,foo)调用集。

如果我们只是调用x:call(Y,foo)，我们可以看到我们没有收到顺序跟踪消息：

10> spawn(fun() -> x:call(Y, foo) end).
<0.55.0>
11> S ! {dump, self()}.
{dump,<0.34.0>}
12> flush().
Shell got []

x:call/2这是因为我们的匹配规范仅在第二个参数是 atom时才启用顺序跟踪trace。

有关更多信息，请参阅手册页，并阅读 Erlang 运行时系统应用程序 (ERTS) 用户指南的seq_trace匹配规范章节。dbg

于 2015-02-12T03:16:29.197 回答