1

我正在重新实现分册 1 中的 Knuth 程序 P：生成前 500 个素数。该程序生成前 25 个素数没有问题。该代码如下：

$ cat progp.S
/* print the first 500 primes */

#define n       %bx
#define j       %r12
#define k       %r13
#define pk      %r14d

        .data
fmt:    .asciz  "%d\n"
x:      .space 1000

        .text
        .globl  main
        .type   main, @function
main:
        pushq   %rbp
        movq    %rsp, %rbp
        xorq    %rbx, %rbx
        movw    $2, x
        movw    $3, n
        movq    $1, j
Mtwo:
        movw    n, x(,j,2)
        incq    j
Mthree:
        cmpq    $500, j
        je      end
Mfour:
        addw    $2, n
Mfive:
        movq    $1, k
Msix:
        movzwl  x(,k,2), pk
        movzwl  n, %eax
        xorq    %rdx, %rdx
        divl    pk
        cmpl    $0, %edx
        je      Mfour
Mseven:
        cmpl    pk, %eax
        jle     Mtwo
Meight:
        incq    k
        jmp     Msix
end:
        xorq    j, j
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        call    printf
        incq    j
        cmpq    $25, j
        je      bye
        jmp     loop
bye:
        movl    $0, %edi
        callq   exit
        leave
        ret
        .size   main,.-main
        .end

如果将 Mthree 中的比较减少到 25，那么程序就可以了。任何更高的程序都会出现故障或在 printf 中挂起。

我正在组装它：

cc -static progp.S

我还可以补充一点，在没有调用 printf 的情况下，它会成功生成前 500 个素数，这可以从在 gdb 中的“结束”处放置一个断点看出。

$ gdb ./a.out
(gdb) b end
Breakpoint 1 at 0x400531
(gdb) run
Starting program: /home/ben/src/hg/asm/knuth/a.out 

Breakpoint 1, 0x0000000000400531 in end ()
(gdb) p $rbx
$1 = 3571

一旦我尝试调用 printf，它就会出错，所以我假设我对堆栈做了一些愚蠢的事情。

4

1 回答 1

3

printf在 x86-64 中期望一个值%rax告诉函数浮点参数的数量。在您的情况下，没有这样的论点，所以很清楚%rax（清除%eax也清除%rax）。您的程序似乎在更改后运行良好：

...
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        xor     %eax, %eax
        call    printf
...
于 2015-02-01T22:09:02.753 回答