55

我有一个以 .vbs 结尾的文本文件，我在其中编写了以下内容：

Set Conn = CreateObject("ADODB.Connection")
Conn.Provider = "Microsoft.ACE.OLEDB.12.0"
Conn.Properties("Data Source") = "C:\dummy.accdb"
Conn.Properties("Jet OLEDB:Database Password") = "pass"
Conn.Open
Conn.Close
Set Conn = Nothing
  • 当我在 Windows 32 位机器上执行此操作时，它运行并结束时没有任何概念（预期）。
  • 当我在 Windows 64 位机器上执行此操作时，会出现错误

    找不到提供者。它可能没有正确安装。

但它已安装。我认为问题的根源在于提供程序是 32 位提供程序，据我所知，它不存在 64 位。

如果我在 64 位机器上通过 IIS 运行 VBScript（作为 ASP 文件），我可以选择它应该在 32 位模式下运行。然后它可以找到提供者。

如何让它在 Windows 64 位上找到提供程序？我可以告诉 CScript（执行 .vbs 文本文件）以某种方式在 32 位模式下运行吗？

4

7 回答 7

78

关注http://support.microsoft.com/kb/896456

要启动 32 位命令提示符，请执行以下步骤：

* Click Start, click Run, type %windir%\SysWoW64\cmd.exe, and then click OK.

然后输入

cscript vbscriptfile.vbs
于 2010-05-10T21:37:55.253 回答
21

WScript.exe存在于两个版本中，一个在目录中C:\Windows\System32\，另一个在C:\Windows\SysWOW64\目录中。它们分别以 64 位和 32 位运行（与立即逻辑相反，但为真）。

您可以在脚本的开头添加以下代码，以便在检测到它以 64 位调用时自动以 32 位重新启动。

请注意，如果它调用自己切换到 64 位，它会传输参数。

' C:\Windows\System32\WScript.exe = WScript.exe
Dim ScriptHost : ScriptHost = Mid(WScript.FullName, InStrRev(WScript.FullName, "\") + 1, Len(WScript.FullName))

Dim oWs : Set oWs = CreateObject("WScript.Shell")
Dim oProcEnv : Set oProcEnv = oWs.Environment("Process")

' Am I running 64-bit version of WScript.exe/Cscript.exe? So, call script again in x86 script host and then exit.
If InStr(LCase(WScript.FullName), LCase(oProcEnv("windir") & "\System32\")) And oProcEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
    ' rebuild arguments
    If Not WScript.Arguments.Count = 0 Then
        Dim sArg, Arg
        sArg = ""
        For Each Arg In Wscript.Arguments
              sArg = sArg & " " & """" & Arg & """"
        Next
    End If

    Dim sCmd : sCmd = """" &  oProcEnv("windir") & "\SysWOW64\" & ScriptHost & """" & " """ & WScript.ScriptFullName & """" & sArg
    'WScript.Echo "Call " & sCmd
    oWs.Run sCmd
    WScript.Quit
End If
于 2013-03-10T09:29:35.100 回答
14

如果您可以控制运行 cscript 可执行文件，则运行X:\windows\syswow64\cscript.exe32 位实现的版本。

于 2010-05-10T21:35:04.323 回答
4

我们可以通过将键“Computer\HKLM\SOFTWARE]\Classes\VBSFile\Shell\Open\Command”的默认值中的“system32”更改为“sysWOW64”来强制 vbscript 始终以 32 位模式运行

于 2015-04-16T10:10:11.537 回答
2 
   ' ***************
   ' *** 64bit check
   ' ***************
   ' check to see if we are on 64bit OS -> re-run this script with 32bit cscript
   Function RestartWithCScript32(extraargs)
   Dim strCMD, iCount
   strCMD = r32wShell.ExpandEnvironmentStrings("%SYSTEMROOT%") & "\SysWOW64\cscript.exe"
   If NOT r32fso.FileExists(strCMD) Then strCMD = "cscript.exe" ' This may not work if we can't find the SysWOW64 Version
   strCMD = strCMD & Chr(32) & Wscript.ScriptFullName & Chr(32)
   If Wscript.Arguments.Count > 0 Then
    For iCount = 0 To WScript.Arguments.Count - 1
     if Instr(Wscript.Arguments(iCount), " ") = 0 Then ' add unspaced args
      strCMD = strCMD & " " & Wscript.Arguments(iCount) & " "
     Else
      If Instr("/-\", Left(Wscript.Arguments(iCount), 1)) > 0 Then ' quote spaced args
       If InStr(WScript.Arguments(iCount),"=") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") + 1) & """ "
       ElseIf Instr(WScript.Arguments(iCount),":") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") + 1) & """ "
       Else
        strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
       End If
      Else
       strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
      End If
     End If
    Next
   End If
   r32wShell.Run strCMD & " " & extraargs, 0, False
   End Function

   Dim r32wShell, r32env1, r32env2, r32iCount
   Dim r32fso
   SET r32fso = CreateObject("Scripting.FileSystemObject")
   Set r32wShell = WScript.CreateObject("WScript.Shell")
   r32env1 = r32wShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%")
   If r32env1 <> "x86" Then ' not running in x86 mode
    For r32iCount = 0 To WScript.Arguments.Count - 1
     r32env2 = r32env2 & WScript.Arguments(r32iCount) & VbCrLf
    Next
    If InStr(r32env2,"restart32") = 0 Then RestartWithCScript32 "restart32" Else MsgBox "Cannot find 32bit version of cscript.exe or unknown OS type " & r32env1
    Set r32wShell = Nothing
    WScript.Quit
   End If
   Set r32wShell = Nothing
   Set r32fso = Nothing
   ' *******************
   ' *** END 64bit check
   ' *******************

将上面的代码放在脚本的开头，随后的代码将在 32 位模式下运行，并可以访问 32 位 ODBC 驱动程序。来源。

于 2013-09-08T23:07:12.780 回答
1

在 64 位机器上运行 32 位脚本的替代方法：%windir%\syswow64\cscript.exe vbscriptfile.vbs

于 2014-05-08T11:06:13.310 回答
1

在启动器脚本中，您可以强制它，它允许为两种架构保留相同的脚本和相同的启动器

:: For 32 bits architecture, this line is sufficent (32bits is the only cscript available)
set CSCRIPT="cscript.exe"
:: Detect windows 64bits and use the expected cscript (SysWOW64 contains 32bits executable)
if exist "C:\Windows\SysWOW64\cscript.exe" set CSCRIPT="C:\Windows\SysWOW64\cscript.exe"
%CSCRIPT% yourscript.vbs
于 2015-04-17T13:01:36.473 回答