oracle - Oracle PLSQL BULK 收集和 For 循环

Question

我编写了以下 oracle 程序来批量获取数据并分块处理。我正在使用带限制的批量收集选项来获取数据。但是在 for 循环中我无法检索 ORD_ID。我正在尝试使用输出 ORD_ID

DBMS_OUTPUT.put_line(l_orders(indx)); 

但出现编译错误“调用‘PUT_LINE’时参数的数量或类型错误”

create or replace PROCEDURE TESTPROC AS 

CURSOR order_id_cur IS SELECT ORD_ID FROM orders ORDER BY ORD_ID ASC;
 l_order_id   VARCHAR2(100);
 TYPE orders_aat IS TABLE OF order_id_cur%ROWTYPE;
 l_orders orders_aat;
 limit_in NUMBER      :=10; 
 batch_in NUMBER :=0;


BEGIN
  OPEN order_id_cur;
  LOOP
    FETCH order_id_cur 
        BULK COLLECT INTO l_orders LIMIT limit_in;
    DBMS_OUTPUT.put_line('Batch-----'||batch_in);
    FOR indx IN 1 .. l_orders.COUNT 
    LOOP
        DBMS_OUTPUT.put_line(indx);
        DBMS_OUTPUT.put_line(l_orders(indx));
    END LOOP;

    EXIT WHEN l_orders.COUNT < limit_in;
    batch_in := batch_in+1;
   END LOOP;
   CLOSE order_id_cur;
END TESTPROC;

如何在 for 循环中获取 ORD_ID 的值。

Answer 1

像这样做 -

DBMS_OUTPUT.put_line(l_orders(indx).ORD_ID);

例如，

SQL> DECLARE
  2  type t
  3  IS
  4    TABLE OF emp%rowtype;
  5    a t;
  6  BEGIN
  7    SELECT * BULK COLLECT INTO a FROM emp;
  8    FOR i IN 1..a.count
  9    LOOP
 10      dbms_output.put_line (a(i).ename);
 11    END LOOP;
 12  END;
 13  /
SMITH
ALLEN
WARD
JONES
MARTIN
BLAKE
CLARK
SCOTT
KING
TURNER
ADAMS
JAMES
FORD
MILLER

PL/SQL procedure successfully completed.

SQL>

Answer 2

您也可以直接循环到光标，如下所示

FOR recc in order_id_cur 
   LOOP
       DBMS_OUTPUT.put_line(recc.ORD_ID );
   END LOOP;