4

我想使用 SPARQL DELETE/INSERT来确保在重复更新?performance和某些连接的空白节点后没有多个属性值，而只有零（对于可选情况）或一个（对于强制情况）。

如果我将 DELETE/INSERT（见下文）发送到 Jena Fuseki 1.1.1 服务器，我会收到以下错误消息：“DELETE 模板中不允许有空白节点”。

但是，规范包含这句话：“DELETE/INSERT 操作可用于删除包含空白节点的三元组。”

那么在这种情况下，有效的 DELETE/INSERT 形式是什么？为便于维护，最好 DELETE 和 INSERT 部分可以保持结构相似。（这是一个后续问题。）

DELETE {
    ?performance
        mo:performer ?_ ;
        mo:singer    ?_ ;
        mo:performance_of [  ### error marked here ###
            dc:title ?_ ;
            mo:composed_in [ a mo:Composition ;
                mo:composer ?_
            ]
        ]
}
INSERT {
    ?performance
        mo:performer ?performer ;     # optional
        mo:singer    ?singer ;        # optional
        mo:performance_of [
            dc:title ?title ;         # mandatory
            mo:composed_in [ a mo:Composition ;
                mo:composer ?composer # optional
            ]
        ]
 }
 WHERE {}
4

1 回答 1

7

你在 WHERE 部分需要一些东西。这将找到 bnodes，将它们放入变量中，然后使用 DELETE 删除它们。DELETE{} 本身不是要匹配的模式 - 图形模式是 WHERE {} 部分。

就像是：

DELETE{
     ?performance
         mo:performance_of ?X .
     ?X dc:title ?title ;
         mo:composed_in ?Y .
     ?Y a mo:Composition .
     ?Y mo:composer ?composer .
     ?performance  mo:performer ?performer ;
                   mo:singer   ?singer
}
WHERE {
    ?performance
         mo:performance_of ?X .
     ?X dc:title ?title ;
         mo:composed_in ?Y .
     ?Y a mo:Composition .
     OPTIONAL { ?Y mo:composer ?composer }
     OPTIONAL { 
           ?performance  mo:performer ?performer ;
                         mo:singer    ?singer 
     }
}

使 DELETE{} 和 INSERT{} 相同是没有意义的 - 它实际上是一个空操作。

如果一个变量在 WHERE{} 部分的特定行中绑定，则删除只是跳过该三元组，而不是实例化模板的其余部分。

对人类来说，分几个部分编写 SPARQL 更新可能更清楚。一个 HTTP 请求可以有多个操作，用“;”分隔：

DELETE{} WHERE {} ;
DELETE{} WHERE {} ;
INSERT DATA{}
于 2015-01-03T11:13:25.633 回答