14

我正在尝试在 Haskell 开发环境中使用 hoogle，就像O'Charles 的 wiki所描述的那样：

shell.nix为了使用，我进行了如下修改hoogleLocal，但它似乎没有为我安装 hoogle 二进制文件。

let
  pkgs = import <nixpkgs> {};

  # I'm attempting to use hoogle here, but it is not working.
  haskellPackages =
    let callPackage = pkgs.lib.callPackageWith haskellPackages;
    in pkgs.recurseIntoAttrs (pkgs.haskellPackages.override {
      extension = self: super: {
        thiscurrentpackage = self.callPackage ./. {};
        hoogleLocal = pkgs.haskellPackages.hoogleLocal.override {
          packages = self.thiscurrentpackage;
        };
      };
    });
in pkgs.myEnvFun {
  name = haskellPackages.thiscurrentpackage.name;
  buildInputs = [
    (haskellPackages.ghcWithPackages (hs: ([
      hs.cabalInstall
      hs.ghcMod
      hs.yesodBin
      # This doesn't appear to install the hoogle binary?
      hs.hoogleLocal
    ] ++ hs.thiscurrentpackage.propagatedNativeBuildInputs)))
  ];
}

在生成的 shell 中，hoogle二进制文件不可用。

如果我包含hs.hoogle在 中buildInputs，则hoogle二进制文件已安装，但找不到数据库。以下是我尝试使用它时发生的情况。

$ nix-shell
......
$ hoogle Monad
Could not find some databases: default
Searching in:
  .
    /nix/store/91y9q2y5a2ws8xgcsx1gkhfagc0f2qz6-haskell-hoogle-ghc7.8.3-4.2.36-shared/share/x86_64-linux-ghc-7.8.3/hoogle-4.2.36/databases

    There are no available databases, generate them with: hoogle data
$ hoogle data
    hoogle: /nix/store/91y9q2y5a2ws8xgcsx1gkhfagc0f2qz6-haskell-hoogle-ghc7.8.3-4.2.36-shared/share/x86_64-linux-ghc-7.8.3/hoogle-4.2.36/databases:
changeWorkingDirectory: does not exist (No such file or directory)
$

对于 O'Charles 所描述的设置，我如何才能使其正常工作？

编辑：原来的 shell.nix 与这个答案相同。

4

3 回答 3

14

这是我的 Nix Haskell 开发环境的样子

在~/.nixpkgs/config.nix：

环境辅助函数

首先，定义一个 haskellEnvFun 函数来构建 Haskell 环境：

packageOverrides = super: rec {

haskellEnvFun = { withHoogle ? false, compiler ? null, name }:
  let hp = if compiler != null
             then super.haskell.packages.${compiler}
             else haskellPackages;

      ghcWith = if withHoogle
                  then hp.ghcWithHoogle
                  else hp.ghcWithPackages;

  in super.buildEnv {
    name = name;
    paths = [(ghcWith myHaskellPackages)];
  };

定义一些环境

调用此函数来定义两种环境：一种用于在更改时运行 Hoogle 构建器，另一种没有：

haskellEnvHoogle = haskellEnvFun {
  name = "haskellEnvHoogle";
  withHoogle = true;
};

haskellEnv = haskellEnvFun {
  name = "haskellEnv";
  withHoogle = false;
};

套餐

定义要在本地 Haskell 开发环境中使用的所有包：

myHaskellPackages = hp: with hp; [
  Boolean
  HTTP
  HUnit
  MissingH
  QuickCheck
  SafeSemaphore
  Spock
  aeson
  async
  attoparsec
  bifunctors
  blaze-builder
  blaze-builder-conduit
  blaze-builder-enumerator
  blaze-html
  blaze-markup
  blaze-textual
  cased
  cassava
  cereal
  comonad
  comonad-transformers
  directory_1_2_4_0
  dlist
  dlist-instances
  doctest
  exceptions
  fingertree
  foldl
  free
  hamlet
  hashable
  hspec
  hspec-expectations
  html
  http-client
  http-date
  http-types
  io-memoize
  keys
  language-c
  language-javascript
  language-bash
  lens
  lens-action
  lens-aeson
  lens-datetime
  lens-family
  lens-family-core
  lifted-async
  lifted-base
  linear
  list-extras
  list-t
  logict
  mime-mail
  mime-types
  mmorph
  monad-control
  monad-coroutine
  monad-loops
  monad-par
  monad-par-extras
  monad-stm
  monadloc
  mongoDB
  monoid-extras
  network
  newtype
  numbers
  optparse-applicative
  parsec
  parsers
  pcg-random
  persistent
  persistent-mongoDB
  persistent-template
  pipes
  pipes-async
  pipes-attoparsec
  pipes-binary
  pipes-bytestring
  pipes-concurrency
  pipes-csv
  pipes-extras
  pipes-group
  pipes-http
  pipes-mongodb
  pipes-network
  pipes-parse
  pipes-safe
  pipes-shell
  pipes-text
  posix-paths
  postgresql-simple
  pretty-show
  profunctors
  random
  reducers
  reflection
  regex-applicative
  regex-base
  regex-compat
  regex-posix
  regular
  relational-record
  resourcet
  retry
  rex
  safe
  sbv
  scotty
  semigroupoids
  semigroups
  shake
  shakespeare
  shelly
  simple-reflect
  speculation
  split
  spoon
  stm
  stm-chans
  stm-stats
  streaming
  streaming-bytestring
  streaming-wai
  strict
  stringsearch
  strptime
  syb
  system-fileio
  system-filepath
  tagged
  taggy
  taggy-lens
  tar
  tardis
  tasty
  tasty-hspec
  tasty-hunit
  tasty-quickcheck
  tasty-smallcheck
  temporary
  test-framework
  test-framework-hunit
  text
  text-format
  time
  tinytemplate
  transformers
  transformers-base
  turtle
  uniplate
  unix-compat
  unordered-containers
  uuid
  vector
  void
  wai
  wai-conduit
  warp
  wreq
  xhtml
  yaml
  zippers
  zlib
];

外壳助手

为了方便起见，在您~/.profile定义了几个 bash 函数来加载这些环境：

环境类型（）{
  环境类型="$1"
  转移
  nix-shell -Q -p $envtype "$@"
}

haskell-env () {
  环境类型“haskellEnv”“$@”
}

haskell-env-hoogle () {
  环境类型“haskellEnvHoogle”“$@”
}

胡格尔

调用haskell-env-hoogle你的shell。这将构建您所有的包 + 文档并将您加载到hoogle范围内的环境中。在这一点上，我通常输入：

hoogle server --local -p 8080 &> /tmp/hoogle.log & disown

在后台启动 hoogle 服务器。最终，我想为此提供一个 systemd 服务，以便我可以通过 nixos-rebuild 重新生成文档并自动启动服务器。

Emacs

对于 emacs，我将其设置haskell-hoogle-url为http://localhost:8080/?hoogle=%s，这样我就可以获得光标下关键字的本地 hoogle 文档。我使用 spacemacs，所以我只是输入, h h这个功能。

您可以在此处查看我的完整 nixpkgs 配置：https ://github.com/jb55/nix-files/blob/659798f2ca81fb7ad0cb5a29de576024ee16eef8/nixpkgs/config.nix#L20

希望有帮助。

于 2015-12-14T00:45:01.830 回答
13

haskellPackages.hoogleLocal似乎已过时；它不存在了。

William Casarin 的回答似乎是假设您将使用一个单一的“haskell 开发环境”，而不是使用 nix-shell 为不同的项目提供不同的开发环境。

我刚刚想出的办法是编写我的 shell.nix 来覆盖ghc.withPackages和ghcWithPackages成为ghc.withHoogle，这样当 nix-shell 创建一个带有 GHC 的环境时，它知道所有必要的包，它还会创建一个 hoogle 数据库知道相同的软件包。

这是我的 shell.nix 1：

{ nixpkgs ? import <nixpkgs> {}, compiler ? "default", withHoogle ? true }:

let

  inherit (nixpkgs) pkgs;

  f = import ./default.nix;

  packageSet = (
    if compiler == "default"
      then  pkgs.haskellPackages
      else  pkgs.haskell.packages.${compiler}
  );

  haskellPackages = (
    if withHoogle
      then  packageSet.override {
              overrides = (self: super:
                {
                  ghc = super.ghc // { withPackages = super.ghc.withHoogle; };
                  ghcWithPackages = self.ghc.withPackages;
                }
              );
            }
      else  packageSet
  );

  drv = haskellPackages.callPackage f {};

in

  if pkgs.lib.inNixShell then drv.env else drv

我对nix很陌生，但我相信这应该是“独立于项目”的；当我更改它时，我可以使用cabal2nix . > default.nix它从我的 cabal 文件中生成一个 nix 包，而无需触摸 shell.nix。

我实际上还没有在实际开发中使用它，只是一个我用来试图弄清楚如何让 hoogle 在 nix-shell 中工作的虚拟项目。

1这个骨架是cabal2nix --shell吐出来的，移除了项目特定的胆量并替换为，f = import ./default.nix而不是再次嵌入 nixified cabal 包。

于 2016-01-04T00:59:35.023 回答
2

使用@Ben 的答案作为参考，这是我需要对cabal2nix --shell文件进行的所需更改的差异：

diff --git a/shell.nix b/shell.nix
index 540ade3..e207d6e 100644
--- a/shell.nix
+++ b/shell.nix
@@ -1,4 +1,4 @@
-{ nixpkgs ? import <nixpkgs> {}, compiler ? "default", doBenchmark ? false }:
+{ nixpkgs ? import <nixpkgs> {}, compiler ? "default", doBenchmark ? false , withHoogle ? true}:

 let

@@ -21,10 +21,23 @@ let
         license = stdenv.lib.licenses.bsd3;
       };

-  haskellPackages = if compiler == "default"
+  haskellPackages' = if compiler == "default"
                        then pkgs.haskellPackages
                        else pkgs.haskell.packages.${compiler};

+  haskellPackages = (
+    if withHoogle
+    then  haskellPackages'.override {
+      overrides = (self: super:
+        {
+          ghc = super.ghc // { withPackages = super.ghc.withHoogle; };
+          ghcWithPackages = self.ghc.withPackages;
+        }
+      );
+    }
+    else haskellPackages'
+  );
+
   variant = if doBenchmark then pkgs.haskell.lib.doBenchmark else pkgs.lib.id;

   drv = variant (haskellPackages.callPackage f {});```
于 2019-07-25T23:34:30.893 回答