9

我有一个 ListView 显示来自 API 的一些数据。在我的列表项中，我需要有两个不同的组件树，具体取决于该行的数据。更具体地说，如果该行有关联的图像，我需要显示带有标签的图像，以某种方式排列。如果它没有图像，那么我只想显示一个标签，以不同的方式排列。对我来说，这听起来像是我想创建两个不同的组件并动态选择要包含的组件。

它目前看起来像这样，缩写形式：

ListItem.Empty {
    id: matchItem
    property string team1Name
    property string team2Name
    property string team1Logo
    property string team2Logo

    width: parent.width

    Item {
        id: team1Info
        width: parent.width*0.3

        anchors {
            left: parent.left
            top: parent.top
            bottom: parent.bottom
        }

        Item {
            anchors.fill: parent
            anchors.margins {
                top: units.gu(2)
                bottom: units.gu(2)
            }

            Image {
                id: team1LogoImage
                source: team1Logo
                width: parent.width
                height: units.gu(5)
                fillMode: Image.PreserveAspectFit
                anchors.horizontalAlignment: parent.horizontalCenter
            }

            Label {
                text: team1Name
                anchors.horizontalAlignment: Text.Center
            }
        }
    }

    // Some more elements and a repeat of the above for the second team
}

问题在于，无论是否team1Logo是team2Logo有效的 URL，例如团队没有徽标，图像组件都会失败。

我想做的基本上是：

if (team1Logo === "") {
    Label {
        // Stuff to make it look good without an image
    }
} else {
    Image {
        source: team1Logo
    }

    Label {
        // Stuff
    }
}

但据我所知，这不是 QML 的工作方式。

我查看了该Loader组件，它似乎符合要求，因为我可以source在加载程序上设置属性时使用条件，但我无法让它工作。有谁知道如何实现我所描述的？

4

2 回答 2

11

事实证明，实现一个Loader. 例子：

Item {
    id: team1Info

    Loader {
        id: team1ItemLoader
        property string name: model.team1Name
        property string logo: model.team1Logo

        source: (logo) ? "TeamLogoItem.qml" : "TeamItem.qml"
    }
}

在这个例子中，name然后logo成为可用的内部TeamLogoItem.qml或TeamItem.qml作为属性。

于 2014-12-30T11:14:53.960 回答
5

@TommyBrunn 的答案仅在TeamItem.qml未定义property您要传入的任何内容时才有效。这意味着：

  • 你不能property alias在你的组件中使用
  • 您不能为此类属性提供任何默认值

或者，您可以使用setSource()for aLoader将属性值传递给加载的组件：

// ### TeamItem.qml (and TeamLogoItem.qml, similarly)
Label {
  property alias name: text
  property string logo: "qrc:/images/logos/dummy.png"
}    

// ### main.qml
Item {
    id: team1Info

    Loader {
        Component.onCompleted: {
            var qml = model.team1Logo ? "TeamLogoItem.qml" : "TeamItem.qml";
            setSource( qml, { name:model.team1Name, logo:model.team1Logo } )
        }
    }
 }

您还可以根据您正在加载的 QML 选择传递不同的属性值——例如，不将徽标传递给 TeamItem.qml。它们不必具有相同的接口。

于 2016-08-15T16:33:20.170 回答