1

XSL 中有什么方法可以更新全局变量吗？

我想检查我已经转换了哪些元素并采取相应的行动。这将需要我以某种方式将元素的名称添加到某种列表中，并在每次转换新元素时更新它。

但是由于xsl:variable它不是人们期望的“变量”，所以一旦它被定义，我就无法添加任何东西。

我有多个包含的数据文件，因此使用只知道当前节点集的 xsl 函数将无济于事。

== 编辑 ==

这就是我现在的转变。但它会包含每次在不同子文件中重复引用的文件。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" />

    <xsl:template match="@*|node()">
        <xsl:copy>
           <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- include the contents of referenced files -->
    <xsl:template match="reference">
        <xsl:apply-templates select="document(@url)/data/node()" />
    </xsl:template>

</xsl:transform>

数据文件看起来像这样：

<data>
    <reference url="another_data_file.xml"/>
    ... other stuff ...
</data>
4

4 回答 4

7

XSLT 是一种函数式语言，不允许更新变量。如果您需要通过多个步骤聚合结果，通常的方法是使用递归模板。例子：

<xsl:template name="transform-elements">
    <xsl:param name="elements-to-process" select="/.."/>
    <xsl:param name="processed-elements" select="/.."/>
    <xsl:if test="$elements-to-process">
        <xsl:variable name="element" select="$elements-to-process[1]"/>

        <!-- ... Do stuff with $element ...-->

        <!-- Recursively invoke template for remaining elements -->
        <xsl:call-template name="transform-elements">
            <xsl:with-param name="elements-to-process" 
                            select="$elements-to-process[position() != 1]"/>
            <xsl:with-param name="processed-elements" 
                            select="$processed-elements|$element"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>
于 2010-05-04T15:21:15.203 回答
1

如果您的输入数据分布在多个文档中，那么将转换过程分成几个步骤可能是个好主意。

添加一个预处理转换，将输入文档中的相关部分提取到单个中间文档中。然后可以使用简单的 XSLT 转换此文档，您可能不会遇到当前面临的问题。

于 2010-05-04T11:09:02.757 回答
1

遗憾的是，没有直接的方法，XSL 变量只能分配一次，但可以有条件地分配。

但是，块中定义的变量只能由该块及其子块访问，也许颠倒您的逻辑并迭代地执行它会起作用吗？

这样，您就无法处理已经转换的东西，因为它已经完成了。

查看 xsl:Key 和 xsl:for-each 的用法，这将使您可以对要转换的节点进行排序。

引用 w3schools 的话，使用这个 XML：

<persons>
  <person name="Tarzan" id="050676"/>
  <person name="Donald" id="070754"/>
  <person name="Dolly" id="231256"/>
</persons>

而这个 XSL：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="preg" match="person" use="@id"/>

<xsl:template match="/">
  <html>
  <body>
  <xsl:for-each select="key('preg','050676')">
    <p>
    Id: <xsl:value-of select="@id"/><br />
    Name: <xsl:value-of select="@name"/>
    </p>
  </xsl:for-each>
  </body>
  </html>
</xsl:template>

</xsl:stylesheet>

将找到 ID 为“050676”的人。也许使用这种方法和更多定义的键会给你你需要的结构？

于 2010-05-04T10:22:31.683 回答
0

我不确定您要解析的文档的大小，但作为相对较小的 XML 文档的解决方案，您可以将结果输出到变量并应用扩展函数节点集（来自 exslt 或 msxsl 等.) 对变量的内容应用转换，排除重复节点，就像处理单个 XML 文档一样。

于 2010-05-04T13:26:57.820 回答