3

我正在使用活动模式来解析 csv 格式的使用日志中的使用事件。下面列出了活动模式部分。解析整个文件效果很好，并且生成的序列充满了各种 UsageEvents。

type SystemName = string
type SystemVersion = string
type MAC = string
type Category = string
type Game = string
type Setting = string
type StartupLocation = string

type UsageEvent =
    | SystemStart of DateTime * SystemVersion * SystemName * MAC
    | SystemEnd of DateTime
    | GameStart of DateTime * Category * Game * Setting * StartupLocation
    | GameEnd of DateTime * Category * Game
    | Other

let (|SystemStart|SystemEnd|GameStart|GameEnd|Other|) (input : string list) =
    match List.nth input 0 with
    | "SystemStartedEvent" ->
         SystemStart (DateTime.Parse (List.nth input 1), List.nth input 2, List.nth input 3, List.nth input 4)
    | "SystemEndedEvent" ->
         SystemEnd (DateTime.Parse (List.nth input 1))
    | "GameStartedEvent" ->
         GameStart (DateTime.Parse (List.nth input 1), List.nth input 2, List.nth input 3, List.nth input 4, List.nth input 5)
    | "GameEndedEvent" ->
         GameEnd (DateTime.Parse (List.nth input 1), List.nth input 2, List.nth input 3)
    | _ ->
         Other

我遇到的问题是我可能以错误的方式使用 ActivePattern。我想根据一些逻辑遍历列表以从中创建一棵树，但我无法在解析后匹配序列中的条目。

let CountSystemStart (entries : UsageEvent list) =
    let rec loop sum = function
        | SystemStart(_,_,_,_) -> sum + 1
        | _ -> sum
    loop 0 entries

这种匹配不起作用，因为循环函数需要一个string list. 我可以通过什么其他方式使用联合中包含的数据，或者我应该匹配输入然后将其存储在常规类型中？

4

2 回答 2

6

要添加到@Petr 的答案 -UsageEvent案例和您的活动模式案例具有相同的名称，因此稍后定义的活动模式会隐藏联合类型。这就是string list事情的来源，很可能。

我会完全放弃活动模式，并将一个Parse函数（或者更确切地说是一个ParseParts，因为你想给它提供一个字符串列表）到UsageEvent.

type UsageEvent =
    | SystemStart of DateTime * SystemVersion * SystemName * MAC
    | (...and so on...)
    static member ParseParts (input: string list) =
        match input with
        | ["SystemStartedEvent"; date; version; name; mac] ->
            SystemStart (DateTime.Parse date, version, name, mac)
        | (...and so on...)

活动模式很可爱，但你真的需要一个好的场景才能让它们发光。否则，如果您可以使用普通函数，只需使用普通函数即可。

于 2014-12-23T01:53:17.160 回答
2

这段代码有两个问题：

  1. 可区分联合UsageEvent和主动模式选择函数具有相同的名称

  2. 递归循环函数在编写时不是递归的 - 它不会调用自身。

当您在 UsageEvent 列表上匹配时，请尝试使用完整的类型名称。

我会将您的 CountSystemStart 函数重写为：

let CountSystemStart (entries : UsageEvent list) =
    let rec loop sum = function
        | [] -> sum 
        | (UsageEvent.SystemStart(_))::rest -> loop (sum + 1) rest
        | _::rest -> loop sum rest
    loop 0 entries
于 2014-12-22T21:07:11.790 回答