2

我正在尝试创建一个批处理文件，该文件将从文本文件中获取用户列表，对 Active Directory 运行 dsquery 以确定帐户是否已被禁用，然后将结果输出到包含用户的不同文本文件ID 以及它们是否已被禁用的状态（是/否）。

我觉得我错误地定位了引号或括号，但我也不能 100% 确定多个“for”语句是否可以像这样嵌套。输入非常感谢。

for /f "tokens=1" %%G in (termlist.txt) do (
for /f "Tokens=*" %%a in ('dsquery user -samid %%G^|dsget user -disabled^| Find /v "disabled"^| Find /v "dsget succeeded"') do set disable=%%a)
echo "%%G %disable%" >> termvalid.txt)
4

3 回答 3

0

嵌套for循环是完全有效的。但是，您需要确保没有任何标记变量会重叠。

for /f "tokens=1,2" %%A in ("hello world") do echo %%A

使用 %%A 和 %%B（因为tokens=1,2），即使只有 %%A 被声明并显式使用，所以下一个要使用的安全变量是 %%C。也就是说，变量区分大小写，因此您可以使用 %%A 到 %%Z 和 %%a 到 %%z，这意味着您在代码中使用它的方式可以正常工作（如果您使用 %%A，只要内部 for 循环没有创建超过 6 个标记）。

于 2014-12-18T00:00:26.683 回答
0
  1. 您省略了每个 ^ 字符实例前面的空格。
  2. 您的整个 FOR 构造被加载为一行（无论它占用多少物理行）......因此 %disable% 在加载整个构造时扩展，并且在运行时不会更改。您可以启用延迟扩展，但在这种情况下不需要这样做。

试试这个（如果你想确保没有附加到旧的不需要的文件，请使用第一行）：

if exist termvalid.txt del /f /q termvalid.txt
for /f "tokens=1" %%G in (termlist.txt) do (
   for /f "Tokens=*" %%a in ('dsquery user -samid %%G ^|dsget user -disabled ^| Find /v "disabled" ^| Find /v "dsget succeeded"') do echo "%%G %%a" >> termvalid.txt))
于 2014-12-18T00:46:17.667 回答
0

有一种简单的方法可以检查多个嵌套命令是否具有正确数量的括号。只需将每个嵌套命令向右缩进三个空格，将左括号放在同一行，右括号放在它关闭的命令的同一列中。例如

for %%a in (set) do (
   for %%b in (set) do (
      if %%a equ %%b (
         then part
      ) else (
         else part
      )
   )
)

当我将这种格式应用于您的代码时，我得到了这个：

for /f "tokens=1" %%G in (termlist.txt) do (
   for /f "Tokens=*" %%a in ('dsquery user -samid %%G^|dsget user -disabled^| Find /v "disabled"^| Find /v "dsget succeeded"') do set disable=%%a
)
echo "%%G %disable%" >> termvalid.txt)

这样，现在很明显还有一个额外的右括号（被忽略），但是 %%G 放在它的 FOR之外。有两种方法可以解决此问题；消除正确的 parenteses 并将 ECHO 移动到正确的位置：

for /f "tokens=1" %%G in (termlist.txt) do (
   for /f "Tokens=*" %%a in ('dsquery user -samid %%G^|dsget user -disabled^| Find /v "disabled"^| Find /v "dsget succeeded"') do set disable=%%a
   echo "%%G !disable!" >> termvalid.txt
)

...或插入遗漏的左括号：

for /f "tokens=1" %%G in (termlist.txt) do (
   for /f "Tokens=*" %%a in ('dsquery user -samid %%G^|dsget user -disabled^| Find /v "disabled"^| Find /v "dsget succeeded"') do (
      set disable=%%a
   )
   echo "%%G !disable!" >> termvalid.txt
)

...除了 %disable% 必须通过延迟访问的问题！变量！扩展，因为它在 FOR 命令中。

于 2014-12-18T01:10:45.890 回答