7

给定一个IScriptObj参考，如何获得相应的IInfoor TProgramInfo？

我有一个包装 Delphi 对象的脚本对象。

为了管理脚本对象的生命周期，Delphi 对象存储了对脚本对象的引用。Script 对象是用一个TdwsUnit组件声明的。这是非常标准的，是这样的：

德尔福

type
  TDelphiObject = class
  private
    FScriptObject: IScriptObj;
  public
    procedure DoSomething;
    property ScriptObject: IScriptObj read FScriptObject write FScriptObject;
  end;

脚本

type
  TScriptObject = class
  protected
    procedure DoSomething; virtual;
  public
    constructor Create;
  end;

Delphi 对象的实例化和 Delphi/脚本链接的设置发生在脚本对象构造函数的 Delphi 实现中。也很标准：

德尔福

// Implements TScriptObject.Create
procedure TMyForm.dwsUnitClassesTScriptObjectConstructorsCreateEval(Info: TProgramInfo; var ExtObject: TObject);
var
  DelphiObject: TDelphiObject;
  DelphiObjectInfo: IInfo;
begin
  // Create the Delphi-side object
  DelphiObject := TDelphiObject.Create;

  // Get the script object "self" value
  DelphiObjectInfo := Info.Vars['self'];

  // Store the ScriptObject reference
  DelphiObject.ScriptObject := DelphiObjectInfo.ScriptObj;

  // Return the instance reference to the script
  ExtObject := DelphiObject;
end;

理想情况下，我会保存IInfo引用，而不是IScriptObj因为之后IInfo会做我需要的一切，但从经验来看，该IInfo对象似乎只在方法调用期间有效。

无论如何，稍后在TDelphiObject.DoSomethingDelphi 端调用时会出现问题。 TDelphiObject.DoSomething旨在调用脚本对象上相应的虚拟方法：

德尔福

procedure TDelphiObject.DoSomething;
var
  Info: IInfo;
  DoSomethingInfo: IInfo;
begin
  // I have a IScriptObj but I need a IInfo...
  Info := { what happens here? };

  // Call the virtual DoSomething method
  DoSomethingInfo := Info.Method['DoSomething'];
  DoSomethingInfo.Call([]);
end;

我尝试了很多不同的技术来获得可用的IInfo或TProgramInfo从存储的IScriptObj，但每件事都失败了。那么这样做的正确方法是什么？

4

1 回答 1

1

问题原来是我认为我需要一个IInfo接口来封装对象实例，但显然 DWScript 不能那样工作。我需要的是创建一个指向实例的临时引用/指针，然后在其IInfo上创建一个。

这是如何完成的：

procedure TDelphiObject.DoSomething;
var
  ProgramExecution: TdwsProgramExecution;
  ProgramInfo: TProgramInfo;
  Data: TData;
  DataContext: IDataContext;
  Info: IInfo;
  DoSomethingInfo: IInfo;
begin
  (*
  ** Create an IInfo that lets me access the object represented by the IScriptObj pointer.
  *)

  // FProgramExecution is the IdwsProgramExecution reference that is returned by
  // TdwsMainProgram.CreateNewExecution and BeginNewExecution. I have stored this
  // elsewhere.
  ProgramExecution := TdwsProgramExecution(FProgramExecution);
  ProgramInfo := ProgramExecution.AcquireProgramInfo(nil);
  try
    // Create a temporary reference object
    SetLength(Data, 1);
    Data[0] := FScriptObject;
    ProgramInfo.Execution.DataContext_Create(Data, 0, DataContext);
    // Wrap the reference
    Info := TInfoClassObj.Create(ProgramInfo, FScriptObject.ClassSym, DataContext);


    // Call the virtual DoSomething method
    DoSomethingInfo := Info.Method['DoSomething'];
    DoSomethingInfo.Call([]);

  finally
    ProgramExecution.ReleaseProgramInfo(ProgramInfo);
  end;
end;

这样做是启用从 Delphi 到脚本的面向对象的回调。如果没有这个，就只能从 Delphi 调用全局脚本函数。

FWIW，上面的以下两行：

ProgramInfo.Execution.DataContext_Create(Data, 0, DataContext);
Info := TInfoClassObj.Create(ProgramInfo, FScriptObject.ClassSym, DataContext);

可以替换为调用CreateInfoOnSymbol（在 dwsInfo 中声明）：

CreateInfoOnSymbol(Info, ProgramInfo, FScriptObject.ClassSym, Data, 0);
于 2014-12-21T18:37:50.300 回答