3

这是游戏

我已经成功地产生了 4 种颜色和 4 个立方体随机混合并遵循链接中建议的配色方案的问题。

因此，目标是使用clpfd. 主要原则是基本的，所有 4 个立方体的同一面必须不同。用于all_different/24 个列表，每个列表都包含由 4 个面组成的“塔”的相应侧面。到现在为止还挺好。

现在我必须确保最终结果是有效移动的组合，并且 4 个立方体的形状必须保持不变。我该怎么做？

我还考虑过实现该图形算法以获得原始问题的可能解决方案，但我真的不知道如何使用约束逻辑编程，甚至不知道这是否可能。

另一方面，和一个也在做这个项目的朋友交谈，他只是在执行我谈到的主要原则。够了吗？花了一些时间在页面上玩弄那个 JavaScript 应用程序，即使立方体是相同的，解决方案似乎有面向不同方向的立方体。

4

2 回答 2

2

你的基本想法是正确的。你确实只需要all_different/1约束。这个谜题的有趣之处在于如何表示立方体。我将采取一种直接的方法，并以与您链接到的页面上给出的几乎完全相同的方式来表示多维数据集。例如，我将表示第一个立方体，其 2D 布局为：

    b
 r  r  r  g
    y

作为基础 Prolog 术语：

tmb(b,[r,r,r,g],y)

其中tmb代表立方体的“顶部、中间、底部”。

最初，我们得到以下 4 个立方体：

cube(tmb(b,[r,r,r,g],y)).
cube(tmb(r,[g,y,g,b],b)).
cube(tmb(r,[b,g,r,y],y)).
cube(tmb(g,[b,r,y,g],y)).

以下谓词将多维数据集与其感兴趣的边相关联：

side_cube(top, tmb(Top,_,_), Top).
side_cube(front, tmb(_,[_,Front|_],_), Front).
side_cube(bottom, tmb(_,_,Bottom), Bottom).
side_cube(back, tmb(_,[_,_,_,Back],_), Back).

现在的重点是：立方体的旋转是什么样的？

cube_rotation(Cube0, Cube) :-
        cube_flip(Cube0, Cube1),
        cube_rotation_(Cube1, Cube).

cube_rotation_(tmb(Top,[A,B,C,D],Bottom), tmb(Top,[E,F,G,H],Bottom)) :-
        append(_, [E,F,G,H|_], [A,B,C,D,A,B,C]).

cube_flip(Cube, Cube).
cube_flip(tmb(Top,[A,B,C,D],Bottom), tmb(A,[Bottom,B,Top,D],C)).
cube_flip(tmb(Top,[A,B,C,D],Bottom), tmb(B,[A,Bottom,C,Top],D)).

练习cube_flip/2：填写完整的解决方案中缺少的 3 个子句。

即使没有 CLP(FD)，现在也很容易描述解决方案：

solution(Cs) :-
        findall(C, cube(C), Cs0),
        same_length(Cs0, Cs),
        maplist(side_different(Cs), [top,front,bottom,back]),
        maplist(cube_rotation, Cs0, Cs).

side_different(Cubes, Side) :-
        maplist(side_cube(Side), Cubes, Colors),
        all_dif(Colors).

all_dif([]).
all_dif([D|Ds]) :- maplist(dif(D), Ds), all_dif(Ds).

即使使用上面给出的代码（正如我所说，它缺少 3 个子句，作为练习我省略了），我们已经找到了两个解决方案：

?- solution(Cubes).
Cubes = [tmb(r,[r,y,r,b],g),tmb(y,[g,b,g,r],b),tmb(b,[y,g,r,y],r),tmb(g,[b,r,y,g],y)] ;
Cubes = [tmb(r,[r,b,r,y],g),tmb(y,[g,r,g,b],b),tmb(b,[r,y,y,g],r),tmb(g,[y,g,b,r],y)] ;
false.

要使用 CLP(FD)，您可以简单地将所有颜色映射到整数，并使用all_different/1（或all_distinct/1，为了更强的传播）而不是all_dif/1.

于 2014-12-14T23:32:31.843 回答
-1

我尝试了自己的运气，没有使用一些地图列表：

:- use_module(library(term/herbrand)).
:- use_module(library(basic/lists)).

solution([C1,C2,C3,C4]) :-
   faces([C1,C2,C3,C4], 2, L2), all_dif(L2),
   faces([C1,C2,C3,C4], 3, L3), all_dif(L3),
   faces([C1,C2,C3,C4], 4, L4), all_dif(L4),
   faces([C1,C2,C3,C4], 6, L6), all_dif(L6),
   cube(1, C1),
   rotate(2, C2),
   rotate(3, C3),
   rotate(4, C4).

% cube(+Integer, -List)
cube(1, [r,y,r,b,r,g]).
cube(2, [g,b,y,r,g,b]).
cube(3, [b,y,g,r,r,y]).
cube(4, [b,y,r,g,y,g]).

% rotate(+Integer, -List)
rotate(S, [X1,X2,X3,X4,X5,X6]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X3,X2,X5,X4,X6,X1]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X5,X2,X6,X4,X1,X3]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X6,X2,X1,X4,X3,X5]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X6,X1,X4,X5,X3,X2]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X4,X1,X3,X5,X2,X6]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X3,X1,X2,X5,X6,X4]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X2,X1,X6,X5,X4,X3]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X2,X6,X5,X3,X4,X1]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X5,X6,X4,X3,X1,X2]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X4,X6,X1,X3,X2,X5]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X1,X6,X2,X3,X5,X4]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X5,X4,X3,X2,X1,X6]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X3,X4,X1,X2,X6,X5]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X1,X4,X6,X2,X5,X3]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X6,X4,X5,X2,X3,X1]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X6,X5,X2,X1,X3,X4]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X2,X5,X3,X1,X4,X6]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X3,X5,X4,X1,X6,X2]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X4,X5,X6,X1,X2,X3]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X2,X3,X1,X6,X4,X5]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X1,X3,X4,X6,X5,X2]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X4,X3,X5,X6,X2,X1]) :- cube(S, [X1,X2,X3,X4,X5,X6]).
rotate(S, [X5,X3,X2,X6,X1,X4]) :- cube(S, [X1,X2,X3,X4,X5,X6]).

% faces(+List, +Integer, -List)
faces([], _, []).
faces([C|L], N, [F|R]) :-
   nth1(N, C, F),
   faces(L, N, R).

% all_dif(+List)
all_dif([]).
all_dif([X|Y]) :-
   all_dif(Y, X),
   all_dif(Y).

% all_dif(+List, +Var)
all_dif([], _).
all_dif([X|Y], Z) :-
   dif(X, Z),
   all_dif(Y, Z).

就像这里瞬间精神错乱一样，我得到了一个独特的解决方案：

Jekejeke Prolog 3, Runtime Library 1.3.8 (May 23, 2019)

?- solution(L).
L = [[r,y,r,b,r,g],[g,b,y,r,g,b],[y,g,b,y,r,r],[b,r,g,g,y,y]] ;
No
于 2019-07-03T21:39:45.220 回答