ant - 如何使用 ANT 将 XML 文件的结构转换为文件夹结构

Question

我希望能够将 XML 文件传递​​给 ANT 构建脚本，并让它创建一个模仿 XML 节点结构的文件夹结构，使用构建文件的父目录作为根目录。

例如使用：

<root>
    <folder1>
         <folder1-1/>
    </folder1>
    <folder2/>
    <folder3>
         <folder3-1/>
    </folder3>
</root>

蚂蚁会创造：

folder1
   -folder1-1
folder2
folder3
   -folder3-1 

我知道如何创建一个目录，但我不确定如何让 ANT 解析 XML。

Answer 1

一种选择是使用 xslt 任务来完成繁重的工作。例如，生成第二个 ant 脚本并调用它。

构建.xml：

<project default="mkdirs">
  <target name="mkdirs">
    <xslt style="mkdir.xslt" in="dirs.xml" out="mkdir.build.xml"/>
    <ant antfile="mkdir.build.xml"/>
  </target>
</project>

将 mkdir.xslt 放在与 build.xml 相同的目录中：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="text()"/>

  <xsl:template match="root">
    <project><xsl:text>&#10;</xsl:text>
      <xsl:apply-templates/>
    </project>
  </xsl:template>

  <xsl:template match="*">
    <mkdir>
      <xsl:attribute name="dir">
        <xsl:for-each select="ancestor::*">
          <xsl:if test="position() != 1">
            <xsl:value-of select="name()"/>
            <xsl:text>/</xsl:text>
          </xsl:if>
        </xsl:for-each>
        <xsl:value-of select="name()"/>
      </xsl:attribute>
    </mkdir><xsl:text>&#10;</xsl:text>

    <xsl:apply-templates/>
  </xsl:template>
</xsl:transform>

xslt 任务的示例 mkdir.build.xml 输出：

<?xml version="1.0" encoding="UTF-8"?><project>
<mkdir dir="folder1"/>
<mkdir dir="folder1/folder1-1"/>
<mkdir dir="folder2"/>
<mkdir dir="folder3"/>
<mkdir dir="folder3/folder3-1"/>
</project>

我不精通 XSLT，因此可以改进 for-each 循环。