5

我有键绑定tmux，我非常喜欢在其中管理拆分窗格：

bind -r H resize-pane -L 5
bind -r J resize-pane -D 5
bind -r K resize-pane -U 5
bind -r L resize-pane -R 5

这让我可以连续用多个 L 击中 L。它还允许我说出我想要增加的边界（左、右等）。

我想在 vim 中有同样的东西，但是 vim 似乎没有边界的上下文：

"attempt 1
nnoremap <leader>L :vertical resize +5<cr><leader>
"attempt 2
nnoremap <leader>L :vertical resize +5<cr>

但是，这仅在最左边的窗格中有效，就像在右边的窗格中一样，我希望它的大小减小 5。此外，这不允许我重复执行此操作。（我想按一次键，然后按我需要的次数按“L”。

我想知道是否有人找到了这样做的方法。

注意：我放置了tmux配置，以便有人可以使用它来确切了解我的意思。

4

2 回答 2

5

我为自己制作了一个 vim 脚本，以使调整大小类似于 Tmux 的行为。这可能是您正在寻找的。

" Tmux-like window resizing
function! IsEdgeWindowSelected(direction)
    let l:curwindow = winnr()
    exec "wincmd ".a:direction
    let l:result = l:curwindow == winnr()

    if (!l:result)
        " Go back to the previous window
        exec l:curwindow."wincmd w"
    endif

    return l:result
endfunction

function! GetAction(direction)
    let l:keys = ['h', 'j', 'k', 'l']
    let l:actions = ['vertical resize -', 'resize +', 'resize -', 'vertical resize +']
    return get(l:actions, index(l:keys, a:direction))
endfunction

function! GetOpposite(direction)
    let l:keys = ['h', 'j', 'k', 'l']
    let l:opposites = ['l', 'k', 'j', 'h']
    return get(l:opposites, index(l:keys, a:direction))
endfunction

function! TmuxResize(direction, amount)
    " v >
    if (a:direction == 'j' || a:direction == 'l')
        if IsEdgeWindowSelected(a:direction)
            let l:opposite = GetOpposite(a:direction)
            let l:curwindow = winnr()
            exec 'wincmd '.l:opposite
            let l:action = GetAction(a:direction)
            exec l:action.a:amount
            exec l:curwindow.'wincmd w'
            return
        endif
    " < ^
    elseif (a:direction == 'h' || a:direction == 'k')
        let l:opposite = GetOpposite(a:direction)
        if IsEdgeWindowSelected(l:opposite)
            let l:curwindow = winnr()
            exec 'wincmd '.a:direction
            let l:action = GetAction(a:direction)
            exec l:action.a:amount
            exec l:curwindow.'wincmd w'
            return
        endif
    endif

    let l:action = GetAction(a:direction)
    exec l:action.a:amount
endfunction

" Map to buttons
nnoremap <M-h> :call TmuxResize('h', 1)<CR>
nnoremap <M-j> :call TmuxResize('j', 1)<CR>
nnoremap <M-k> :call TmuxResize('k', 1)<CR>
nnoremap <M-l> :call TmuxResize('l', 1)<CR>

您可以使用该TmuxResize功能将其他键映射到它。第一个参数是方向（'h'、或） 'j'，第二个参数是分割边框应该移动多少。'k''l'

于 2016-04-15T17:32:43.433 回答
0

有一些插件可以做到这一点。例如tinymode、submode和tinykeymap

至少对于 tinykeymap，这曾经是默认行为，当按下Ctrl+时它会切换到 tmux 行为+（这就是原因，我最终卸载了那个插件）

于 2014-12-03T18:57:33.833 回答