clojure - Clojure：从序列中查找连续项目

Question

在 Clojure 程序中，我有一个数字序列：

(2 3 4 6 8 1)

我想找到项目是连续的最长的子序列：

(2 3 4)

我假设它将涉及(take-while ...)or (reduce ...)。

有任何想法吗？

澄清：我需要最长的顺序项目初始列表。容易多了，我敢肯定。感谢我最初提出的更困难问题的解决方案。

Answer 1

如果您只对最长的初始序列感兴趣，它是一个 1-liner：

(defn longest-initial-sequence [[x :as s]]
  (take-while identity (map #(#{%1} %2) s (iterate inc x))))

Answer 2

考虑到 OP 对这个问题的评论——这完全改变了游戏！-- 这可以写得很简单：

(let [doubletons (partition 2 1 [1 2 3 5 6])
      increment? (fn increment? [[x y]]
                   (== (inc x) y))]
  (cons (ffirst doubletons)
        (map second (take-while increment? doubletons))))

;; returns (1 2 3)

请注意，这实际上是懒惰的。doubletons我希望它不会因为当地人的清理而占据主导地位。另一个版本：

(cons (first [1 2 3 5 6])
      (map second (take-while increment? (partition 2 1 [1 2 3 5 6]))))

不过，问题的原始版本更有趣！:-) 可以使用上面的方法构建一个超级简单的解决方案，但当然这比使用reduce. 我会看看我是否有任何与 zmila 和 dnolen 的解决方案有很大不同的东西——但仍然具有合理的性能——以便稍后添加到这个线程的那个部分。（不太可能，我猜。）

Answer 3

回复原文：

(defn conj-if-sequential
  ([] [])
  ([a] a)
  ([a b] (let [a (if (vector? a) a [a])]
           (if (= (inc (last a)) b)
             (conj a b)
             a))))

(reduce conj-if-sequential [2 3 4 6 8 1])

对于那些感兴趣的人来说，一个更通用的解决方案：

(defn sequential-seqs
  ([] [])
  ([a] a)
  ([a b] (let [n (last (last a))]
           (if (and n (= (inc n) b))
             (update-in a [(dec (count a))] conj b)
             (conj a [b])))))

(defn largest
  ([] nil)
  ([a] a)
  ([a b] (if (> (count b) (count a)) b a)))

(reduce largest (reduce sequential-seqs [] [2 3 4 6 8 1 4 5 6 7 8 9 13]))

我认为这要好得多。

Answer 4

(defn find-max-seq [lst]
  (let [[f & r] lst, 
        longest-seq (fn [a b] (if (> (count a) (count b)) a b)),
        [last-seq max-seq] (reduce 
                             (fn [ [[prev-num & _ :as cur-seq] max-seq] cur-num ]
                               (if (== (inc prev-num) cur-num) 
                                 [(conj cur-seq cur-num) max-seq]
                                 [(list cur-num) (longest-seq cur-seq max-seq)]
                                 ))
                             [(list f) ()]
                             r)]
    (reverse (longest-seq last-seq max-seq))))

(find-max-seq '(2 3 4 6 8 1))  ; ==> (2 3 4) 
(find-max-seq '(3 2 3 4 6 8 9 10 11)) ; ==> (8 9 10 11)