xml - 删除 xslt 中具有相同 id 的第二个节点

Question

我需要使用 XSLT 2.0 在 xml 文件中删除一些具有相同 ID 的节点。结构是：

<Root>
  <media tipo="immagine" id="1">
    <numero>14.1</numero>
  </media>
  <media tipo="immagine" id="2">
    <numero>14.2</numero>
  </media>
  <media tipo="immagine" id="1">
    <numero>14.1</numero>
  </media>
</Root>

结果必须是：

<Root>
  <media tipo="immagine" id="1">
    <numero>14.1</numero>
  </media>
  <media tipo="immagine" id="2">
    <numero>14.2</numero>
  </media>
</Root>

我有多个具有相同属性 ID 值。谢谢

Answer 1

假设 id 是您想要比较和检查使用的所有内容

<xsl:key name="by-id" match="*" use="@id"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*[@id and not(. is key('by-id', @id)[1])]"/>

Answer 2

由于您使用的是XSLT 2.0，因此您可以执行以下操作：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/Root">
    <Root>
        <xsl:for-each-group select="media" group-by="@id">
            <xsl:copy-of select="current-group()[1]"/>
        </xsl:for-each-group>
    </Root>
</xsl:template>

</xsl:stylesheet>