vb.net - 在构建时设置常量或变量的值

Question

我想在我的应用程序启动代码中定义一个常量或字段，以反映应用程序实际构建的日期。例如：

 Private Shared ApplicationBuiltOn As Date = <and here is where I would like to set the build date>`

这是否可以使用构建事件来完成，以便始终设置它并且我不必主动记住在主动构建发布版本之前这样做。

如果有可能怎么做？我已经阅读了有关构建事件的 msdn 文档，但似乎没有任何内容涵盖我想要尝试和做的事情。

Answer 1

你可以试试这个（测试它并为我工作）

Public NotInheritable Class ApplicationInformation
    Private Sub New()
    End Sub
    ''' <summary>
    ''' Gets the executing assembly.
    ''' </summary>
    ''' <value>The executing assembly.</value>
    Public Shared ReadOnly Property ExecutingAssembly() As System.Reflection.Assembly
        Get
            Return If(m_executingAssembly, (InlineAssignHelper(m_executingAssembly, System.Reflection.Assembly.GetExecutingAssembly())))
        End Get
    End Property
    Private Shared m_executingAssembly As System.Reflection.Assembly

    ''' <summary>
    ''' Gets the executing assembly version.
    ''' </summary>
    ''' <value>The executing assembly version.</value>
    Public Shared ReadOnly Property ExecutingAssemblyVersion() As System.Version
        Get
            Return If(m_executingAssemblyVersion, (InlineAssignHelper(m_executingAssemblyVersion, ExecutingAssembly.GetName().Version)))
        End Get
    End Property
    Private Shared m_executingAssemblyVersion As System.Version

    ''' <summary>
    ''' Gets the compile date of the currently executing assembly.
    ''' </summary>
    ''' <value>The compile date.</value>
    Public Shared ReadOnly Property CompileDate() As System.DateTime
        Get
            If Not m_compileDate.HasValue Then
                m_compileDate = RetrieveLinkerTimestamp(ExecutingAssembly.Location)
            End If
            Return If(m_compileDate, New System.DateTime())
        End Get
    End Property
    Private Shared m_compileDate As System.Nullable(Of System.DateTime)

    ''' <summary>
    ''' Retrieves the linker timestamp.
    ''' </summary>
    ''' <param name="filePath">The file path.</param>
    ''' <returns></returns>
    ''' <remarks>http://www.codinghorror.com/blog/2005/04/determining-build-date-the-hard-way.html</remarks>
    Private Shared Function RetrieveLinkerTimestamp(filePath As String) As System.DateTime
        Const  peHeaderOffset As Integer = 60
        Const  linkerTimestampOffset As Integer = 8
        Dim b = New Byte(2047) {}
        Dim s As System.IO.FileStream = Nothing
        Try
            s = New System.IO.FileStream(filePath, System.IO.FileMode.Open, System.IO.FileAccess.Read)
            s.Read(b, 0, 2048)
        Finally
            If s IsNot Nothing Then
                s.Close()
            End If
        End Try
        Dim dt = New System.DateTime(1970, 1, 1, 0, 0, 0).AddSeconds(System.BitConverter.ToInt32(b, System.BitConverter.ToInt32(b, peHeaderOffset) + linkerTimestampOffset))
        Return dt.AddHours(System.TimeZone.CurrentTimeZone.GetUtcOffset(dt).Hours)
    End Function
    Private Shared Function InlineAssignHelper(Of T)(ByRef target As T, value As T) As T
        target = value
        Return value
    End Function
End Class

并像这样使用它：

Messagebox.Show("This application was built on: " & ApplicationInformation.CompileDate.ToString())

注意：从https://stackoverflow.com/a/3634544/4237809和http://blog.codinghorror.com/determining-build-date-the-hard-way/一起抓取